Início / coding / Perguntas / 76930878
Accepted
kodster17
Asked: 2023-08-18 23:53:40 +0800 CST

Como posso retornar linhas específicas onde EXISTE uma taxa no contrato listado, mas NÃO há taxa no sistema?

  • 772

Tenho um conjunto de dados de informações de cobrança em uma guia e, na próxima guia, gostaria de ver apenas as linhas em que há uma taxa na coluna do contrato, mas nenhuma taxa mostrada/salva no sistema.

Seria como uma guia somente para visualização. Idealmente, gostaria que mudasse/reagisse automaticamente às mudanças na primeira guia. visual

Tentei usar VSTACK( )&, FILTER( )mas continuei recebendo um erro #value.

excel

1 respostas

  1. Best Answer

    Tente usar a seguinte fórmula:

    insira a descrição da imagem aqui

    • Fórmula usada na célulaA7

    =VSTACK(A1:D1,FILTER(A2:D4,(D2:D4>0)*IFERROR(C2:C4,0)=0))

    ParaNon-MS365

    insira a descrição da imagem aqui

    • Fórmula usada na célulaA12

    =IFERROR(INDEX($A$2:$D$4,AGGREGATE(15,6,(ROW($A$2:$D$4)-ROW($A$2)+1)/
  (($D$2:$D$4>0)*(IFERROR($C$2:$C$4,0)=0)),ROWS(A$12:A12)),),"")

    Ressalva garantir ao sair da fórmula para acertar CTRL+ SHIFT+ ENTERe não apenasENTER

    Além disso, você pode usar este também.

    =IFERROR(INDEX($A$2:$D$4,AGGREGATE(15,6,(ROW($A$2:$D$4)-ROW($A$2)+1)/
 (($D$2:$D$4>0)*(IFERROR($C$2:$C$4,0)=0)),ROWS($A$12:$A12)),MATCH(A$11,$A$1:$D$1,0)),"")

    Onde você precisa preencher direito e preencher!

    Ou você também pode extrair os dados dessa maneira.

    insira a descrição da imagem aqui

    • Fórmula usada na célulaA7

    =LET(
     a,A1:E4,
     b,TAKE(a,1),
     c,DROP(a,1),
     d,INDEX(c,,3),
     e,INDEX(c,,4),
     DROP(VSTACK(b,FILTER(c,(e>0)*(IFERROR(d,0)=0))),,-1))

    Atualizada:

    insira a descrição da imagem aqui

    =LET(
     a,A1:F4,
     b,TAKE(a,1),
     c,DROP(a,1),
     d,INDEX(c,,4),
     e,INDEX(c,,5),
     f,FILTER(c,(e>0)*(IFERROR(d,0)=0)),
     DROP(VSTACK(b,IF(f=0,"",f)),,-1))
    • 1

relate perguntas