Início / coding / Perguntas / 76926477
Accepted
Mahavir
Asked: 2023-08-18 12:41:34 +0800 CST

Visualizando caracteres ocultos

  • 772

Eu tenho essa função para visualizar caracteres '︁' (0xfe01) ocultos. Isso poderia ser mais geral para que todos os caracteres ocultos em uma string sejam visualizados?

 (defun my-display-hidden (&optional remove)
  "Show/hide the hidden '︁' (0xfe01) characters."
  (interactive "P")
  (if remove (remove-overlays)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward "︁" nil t) ; (0xfe01)
        (let ((ov (make-overlay (match-beginning 0) (match-end 0))))
          (overlay-put ov 'display
                       (buttonize "(0xfe01)"
                                  (let ((pos (match-beginning 0)))
                                    (lambda (_) (describe-char pos)))))
          (overlay-put ov 'face 'font-lock-warning-face))))))
emacs

1 respostas

  1. Best Answer

    Essa função pode ser estendida para exibir caracteres não-ascii de largura zero de maneira semelhante ao seguinte.

    (defun my-show-nonascii (&optional remove all)
  "Toggle display of zero-width non-ascii characters in current buffer.
With prefix \\[universal-argument] REMOVE, remove displays.
With prefix \\[universal-argument] \\[universal-argument] ALL show all non-ascii chars."
  (interactive (list (eq 4 (prefix-numeric-value current-prefix-arg))
                     (eq 16 (prefix-numeric-value current-prefix-arg))))
  (if remove (remove-overlays (point-min) (point-max) 'nonascii t)
    (save-excursion
      (goto-char (point-min))
      (while (re-search-forward "[[:nonascii:]]" nil t)
        (when (or all (zerop (char-width (char-after (match-beginning 0)))))
          (let ((ov (make-overlay (match-beginning 0) (match-end 0))))
            (overlay-put ov 'display
                         (buttonize (format "(%d)" (char-after (match-beginning 0)))
                                    (let ((pos (match-beginning 0)))
                                      (lambda (_) (describe-char pos)))))
            (overlay-put ov 'face 'font-lock-warning-face)
            (overlay-put ov 'nonascii t)))))))
    • 0

relate perguntas