Início / coding / Perguntas / 76922512
Accepted
Rajat Kumar
Asked: 2023-08-17 22:31:45 +0800 CST

Como usar a função de tecla XSLT 3.0

  • 772

Tenho uma fonte de dados XML que contém o nome do país, desejo substituí-la pelo código do país. O país pode ser qualquer país do mundo. Eu tentei fazer isso usando a função de chave, mas continua me dando valor nulo na saída final do json.

=== Meus Dados XML do Soap ===

<?xml version="1.0" encoding="UTF-8"?>
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  xmlns="urn:enter.soap.force.com"
  xmlns:sf="urn:sobject.enter.soap.force.com"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
  <soapenv:Body>
    <queryMoreResponse>
      <result>
        <records xsi:type="sf:CaseData">
          <sf:Id>6896ADSD888</sf:Id>
          <sf:Number>123456666</sf:Number>
          <sf:ConsumerCountry>Australia</sf:ConsumerCountry>
        </records>
                <records xsi:type="sf:CaseData">
          <sf:Id>6896SDRGGG666</sf:Id>
          <sf:Number>123456666</sf:Number>
          <sf:ConsumerCountry>United States</sf:ConsumerCountry>
        </records>
      </result>
    </queryMoreResponse>
  </soapenv:Body>
</soapenv:Envelope>

Eu tentei com 3 países que podem se estender para mais de 50 ou 100

=== Minha folha de estilo XSLT 3.0 ====

<xsl:stylesheet version="3.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
  xmlns:sf="urn:sobject.enter.soap.force.com" xpath-default-namespace="urn:enter.soap.force.com"
  xmlns:mf="http://example.com/mf" exclude-result-prefixes="#all">
    
    
    <!-- starts: What I tried -->
  <xsl:key name="countryCodes" match="sf:country" use="sf:name" />
 
  <sf:country name="United States">US</sf:country>
  <sf:country name="Australia">AU</sf:country>
  <sf:country name="Germany">DE</sf:country>
    <!-- ends: What I tried -->
    
    <xsl:function name="mf:process-records" as="item()*">
        <xsl:param name="elements" as="element()*"/>
        <xsl:apply-templates select="$elements"/>
  </xsl:function>

  <xsl:output method="json" indent="yes"/>

  <xsl:template match="/soapenv:Envelope">
    <xsl:map>
      <xsl:map-entry key="'caserecords'" select="array { mf:process-records(soapenv:Body/queryMoreResponse/result/records) }"/>
    </xsl:map>
  </xsl:template>
    <xsl:template match="records">
        <xsl:map-entry key="'case'">
            <xsl:map>
                <xsl:map-entry key="'report'">
                        <xsl:map>
                            <xsl:map-entry key="'reportid'" select="string(sf:Id)"/>
                            <xsl:map-entry key="'reportnumber'" select="string(sf:Number)"/>
                            <!-- starts: What I tried -->
                            <xsl:variable name="countryName" select="string(sf:ConsumerCountry)" />
                            <xsl:variable name="countryCode" select="key('countryCodes', $countryName)" />
                            <xsl:map-entry key="'sourcecountry'" select="$countryCode"/>
                            <!-- ends: What I tried -->
                        </xsl:map>
                </xsl:map-entry>
            </xsl:map>
        </xsl:map-entry>
    </xsl:template>
</xsl:stylesheet>

Saída Esperada

{
   "records": [
      {
         "case": {
            "safetyreport": {               
               "reportid": "6896ADSD888",
               "reportnumber": "123456666",
               "sourcecountry": "AU",
               
            }
         }
      },
            {
         "case": {
            "safetyreport": {               
               "reportid": "6896SDRGGG666",
               "reportnumber": "123456666",
               "sourcecountry": "US",
               
            }
         }
      },
   ]
}
json

2 respostas

  1. Considere o seguinte exemplo simplificado :

    <xsl:stylesheet version="3.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/"
xmlns:sf="urn:sobject.enter.soap.force.com"
xpath-default-namespace="urn:enter.soap.force.com"
xmlns:my="http://example.cpm/my"
exclude-result-prefixes="#all">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="countryCode" match="my:country" use="@name" />

<xsl:variable name="countryCodes">
    <my:country name="United States">US</my:country>
    <my:country name="Australia">AU</my:country>
    <my:country name="Germany">DE</my:country>
</xsl:variable>

<xsl:template match="/soapenv:Envelope">
    <root>
        <xsl:apply-templates select="soapenv:Body/queryMoreResponse/result/records"/>
    </root>
</xsl:template>

<xsl:template match="records">
    <record>
        <country>
            <xsl:value-of select="sf:ConsumerCountry"/>
        </country>
        <countryCode>
            <xsl:value-of select="key('countryCode', sf:ConsumerCountry, $countryCodes)"/>
        </countryCode>
    </record>
</xsl:template>

</xsl:stylesheet>

    Aplicado ao seu exemplo de entrada, isso retornará:

    <?xml version="1.0" encoding="UTF-8"?>
<root>
   <record>
      <country>Australia</country>
      <countryCode>AU</countryCode>
   </record>
   <record>
      <country>United States</country>
      <countryCode>US</countryCode>
   </record>
</root>
    • 1
  2. Best Answer

    Eu sugeriria (dado que você usa XSLT 3 e parece querer definir o mapeamento de nomes de países para codificar em linha) declarar um parâmetro de mapa global, por exemplo

    <xsl:param name="countryCodes" as="map(xs:string,xs:string)"
  select="map {
           'United States' : 'US',
           'Australia' : 'AU',
           'Germany' : 'DE'
         }"/>

    (em sua amostra XSLT, você precisa declarar o prefixo xmlns:xs="http://www.w3.org/2001/XMLSchema") e, em seguida, use, por exemplo

    <xsl:map-entry key="'sourcecountry'" select="$countryCodes(sf:ConsumerCountry)"/>
    • 0

relate perguntas