Início / coding / Perguntas / 76920836
Accepted
Vinograd
Asked: 2023-08-17 18:56:19 +0800 CST

Erro de compilação usando CMake com biblioteca [fechada]

  • 772

Estou tentando criar um projeto CMake com 2 alvos. Um deles deve ser uma biblioteca e o outro um executável. Mas quando tento construir o executável, recebo um erro dizendo que a biblioteca não foi encontrada.

Biblioteca CMake:

file(GLOB SOURCES ${CMAKE_CURRENT_LIST_DIR}/src/*.cpp)

set(HEADERS include)

add_library(arcade-lib STATIC ${SOURCES})

target_include_directories(arcade-lib PUBLIC ${HEADERS})
target_link_libraries(arcade-lib PRIVATE sfml-window sfml-graphics)

CMake executável:

file(GLOB SOURCES ${CMAKE_CURRENT_LIST_DIR}/src/*.cpp)
set(INCLUDE include)

set(ARCADE_GAMES_LIB_INCLUDE ../arcade-games-lib/include)

add_executable(snake-game snake-game.cpp ${SOURCES})

target_link_libraries(snake-game PRIVATE arcade-games-lib sfml-graphics sfml-window sfml-system sfml-main )
target_include_directories(snake-game PRIVATE ${INCLUDE} ${ARCADE_GAMES_LIB_INCLUDE})

CMake principal:

cmake_minimum_required(VERSION 3.25)
project(arcade_games)

set(CMAKE_CXX_STANDARD 20)

set(CMAKE_EXE_LINKER_FLAGS "-static -static-libgcc")
set(SFML_STATIC_LIBRARIES TRUE)

find_package(SFML 2.5 COMPONENTS graphics window system REQUIRED)

add_subdirectory(arcade-games-lib)

add_subdirectory(snake-game)

Mensagem de erro:

C:\Program Files\JetBrains\CLion 2022.3.2\bin\mingw\bin/ld.exe: cannot find -larcade-games-lib
collect2.exe: error: ld returned 1 exit status
ninja: build stopped: subcommand failed.

Eu nem sei o que fazer, porque tudo parece certo. Eu esperava que um arquivo executável fosse criado que incluísse minha biblioteca

c++

1 respostas

  1. Best Answer

    O problema, conforme apontado nos comentários, era que os nomes da biblioteca add_librarye target_link_librariesprecisavam corresponder.

    Usar file(GLOBpara coletar arquivos de origem é problemático, conforme apontado por @Botje e em Por que o arquivo cmake GLOB é mau?

    Tomei a liberdade de remover um pouco do seu CMakeLists.txt:

    Biblioteca CMake:

    add_library(arcade-lib STATIC 
  src/foo.cpp
  src/bar.cpp
  include/my_header.h # the compiler will work without it but headers may not show up in IDEs
)

target_include_directories(arcade-lib PUBLIC include) # no need for a variable, just use relative path
target_link_libraries(arcade-lib PRIVATE sfml-window sfml-graphics)

    CMake executável:

    # no need for ARCADE_GAMES_LIB_INCLUDE once you specify the right library name

add_executable(snake-game 
  snake-game.cpp
  src/more_snake.cpp
)

# use the same library name you used in add_library:
target_link_libraries(snake-game PRIVATE arcade-lib sfml-graphics sfml-window sfml-system sfml-main)
target_include_directories(snake-game PRIVATE include)
    • 3

relate perguntas