Início / coding / Perguntas / 76920505
Accepted
CarLaTeX
Asked: 2023-08-17 18:07:11 +0800 CST

Não consigo importar um txt iso-8859-1 em SAS (sessão UTF-8)

  • 772

Eu tenho o arquivo prova.txt:

01                                                                                                                                                                                                                                                       ±00CC00   2023-07-21
50                                               MSTAT»BR_02»BR_07»BR_14                                                                                                                                                                                 ±000066   2023-07-19
01                                                                                                                                                                                                                                                       ±00CC00   2023-07-21

que tem esta codificação ( file -bi prova.txt):

text/plain; charset=iso-8859-1

Estou tentando importá-lo no SAS com este programa:

libname pathdata "/my/dir/dataset";

filename inp "/my/dir/file/prova.txt";
    
data pathdata.prova;
Infile inp /*encoding="wlatin1"*/ lrecl=270 DSD MISSOVER PAD firstObs=1;                                                                                                                                                                                                         
Attrib colore length=$49                                                                                                                                                                                                                            
format=$char49. informat=$char49. ;                                                                                                                                                                               
Attrib orig length=$200                                                                                                                                                                                                                         
format=$char200. informat=$char200. ;                                                                                                                                                                        
Attrib app length=$10                                                                                                                                                                                                                        
format=$char10. informat=$char10. ;                                                                                                                                      
Attrib data_v length=$10                                                                                                                                                                                                                             
format=$char10. informat=$char10.;                                                                                                                                                                                                    

  Input
        @1 colore $char49.
        @50 orig $char200.
        @250 app $char10.
        @260 data_v $char10.
;

run;

Se eu não usar, encoding="wlatin1"recebi caracteres errados no conjunto de dados SAS:

insira a descrição da imagem aqui

Se eu usar, encoding="wlatin1"obtive os caracteres corretos, mas as seguintes variáveis ​​​​são alteradas:

insira a descrição da imagem aqui

A codificação da sessão é ENCODING=UTF-8.

encoding

1 respostas

  1. Best Answer

    Leia-o com ENCODING=ANY e, em seguida, transcodifique as strings você mesmo.

    Certifique-se de definir as variáveis ​​por tempo suficiente para manter a versão UTF-8 do texto, portanto, mais do que o número de bytes lidos do arquivo.

    data test;
  infile inp encoding="any" truncover; 
  length colore $60 orig $250 app $15 data_v $15 ;
  input colore $char49. orig $char200. app $char10. data_v $char10. ;
  array _c _character_;
  do over _c;
    _c=kcvt(_c,'wlatin1','utf-8');
  end;
run;

    Ou leia o arquivo usando a codificação WLATIN1, mas extraia as strings da variável _INFILE_ usando KSUBSTR() em vez da instrução INPUT.

    data test;
  infile inp encoding="wlatin1" truncover; 
  length colore $60 orig $250 app $15 data_v $15 ;
  input ;
  colore =ksubstr(_infile_,1,49);
  orig =ksubstr(_infile_,50,200);
  app =ksubstr(_infile_,250,10);
  data_v = ksubstr(_infile_,260,10);
run;

    insira a descrição da imagem aqui

    O motivo pelo qual você está tendo problemas ao usar ENCODING="WLATIN1" ao ler o arquivo em uma sessão SAS que está usando a codificação UTF-8 é que as linhas são transcodificadas durante a leitura. Portanto, a localização na linha do campo APP e DATA_V se move quando os caracteres não ASCII são transcodificados de byte único para byte múltiplo.

    Se você não quisesse ler por posição de coluna, mas tivesse um tipo delimitado, como um arquivo CSV, não teria problemas.

    • 2

relate perguntas