主页 / dba / 问题 / 9441
Accepted
bernd_k
Asked: 2011-12-20 22:56:15 +0800 CST

如何仅捕获和处理特定的 Oracle 异常？

  • 772

从这个和这个我猜，ORA-00955 没有预定义的命名系统异常。

如何重写以下内容以仅捕获错误 ORA-00955？

begin
      EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
exception when OTHERS then
    Null;
end;

顺便说一句，是否有任何语法可以通过提供错误代码来捕获错误？

oracle exception

2 个回答

  1. Best Answer

    你有两个选择：

    直接按编号引用异常：

    BEGIN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
EXCEPTION
    WHEN OTHERS THEN
      IF SQLCODE = -955 THEN
        NULL; -- suppresses ORA-00955 exception
      ELSE
         RAISE;
      END IF;
END;

    其他选项是使用EXCEPTION_INITPragma 指令将已知的 Oracle 错误号绑定到用户定义的异常；

    DECLARE
   name_in_use exception; --declare a user defined exception
   pragma exception_init( name_in_use, -955 ); --bind the error code to the above 
BEGIN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
EXCEPTION
    when name_in_use then
       null; --suppress ORA-00955 exception
END;

    顺便说一句，是否有任何语法可以通过提供错误代码来捕获错误？

    是的，我已经在第一个例子中演示过了

    进一步阅读这方面的变化：

    • 37

  2. 类似于 Sathya 已经提出的建议，但when others如果可能的话，我希望完全避免 - 对于您没有专门处理的异常，未处理的异常通常是正确的结果：

    create sequence foo;
/*
sequence FOO created.
*/
declare
  name_is_already_used_955 exception;
  pragma exception_init(name_is_already_used_955,-955);
begin
  execute immediate 'create sequence foo';
exception when name_is_already_used_955 then null;
end;
/
/*
anonymous block completed
*/
    • 5

相关问题