主页 / dba / 问题 / 62130
Accepted
Peter PitLock
Asked: 2014-03-31 23:58:47 +0800 CST

在存储过程中，根据变量设置返回查询的列名

  • 772

我有一个我想重用的查询，而不是仅仅为了更改列名而拥有许多不同的副本。

报告（例如）使用相同的查询，但表中有狗或猫，如果有猫，则返回“Nr of Cats”，如果有狗，则返回“Nr of Dogs”作为标题返回的表。

declare @Animals table (
  AnimalType varchar(20), Name varchar(20)
  )

insert into @Animals(Type, Name) values('Cat', 'Garfield')

declare @AnimalType varchar(20)

set @AnimalType = (Select Top 1  AnimalType from @Animals )

select 
    Case when @AnimalType = 'Cat' 
           then 'Nr of Cats' 
           else 'Nr of Dogs' = count(*)  from @Animals
sql-server-2005 temporary-tables

1 个回答

  1. Best Answer

    如果您确实希望 SQL Server 使用可变列名传回结果，则需要为此使用动态 SQL。

    举例来说，考虑以下内容：

    使用 tempdb 避免对现有对象造成任何令人讨厌的意外：

    USE tempdb;

    创建一个表来保存示例数据。由于我们使用的是动态 SQL，因此我们不能为此使用表变量。

    IF OBJECT_ID('dbo.Animals') IS NOT NULL
DROP TABLE dbo.Animals;

CREATE TABLE dbo.Animals 
(
    AnimalType varchar(20) NOT NULL
    , AnimalName varchar(20) NOT NULL
);

INSERT INTO dbo.Animals (AnimalType, AnimalName)
VALUES ('Cat', 'Garfield')
    , ('Dog', 'Lucy');

GO

    使用动态 T-SQL 创建存储过程：

    IF OBJECT_ID('dbo.DynamicResults') IS NOT NULL
DROP PROCEDURE dbo.DynamicResults;
GO
CREATE PROCEDURE dbo.DynamicResults
(
    @DogsOrCats varchar(3)
)
AS
BEGIN
    SET NOCOUNT ON;
    DECLARE @msg nvarchar(1000);
    IF (@DogsOrCats = 'Dog' OR @DogsOrCats = 'Cat')
    BEGIN
        DECLARE @cmd nvarchar(max);
        DECLARE @vars nvarchar(max);
        SET @vars = '@Type varchar(20)';
        SET @cmd = 'SELECT a.AnimalType
            , [NumberOf' + @DogsOrCats + 's] = COUNT(1)
        FROM dbo.Animals a
        WHERE a.AnimalType = @Type
        GROUP BY a.AnimalType;';
        EXEC sys.sp_executesql @cmd, @vars, @Type = @DogsOrCats;
    END
    ELSE
    BEGIN
        SET @msg = '@DogsOrCats must be either ''Dog'' or ''Cat''';
        RAISERROR (@msg, 14, 1) WITH NOWAIT;
    END
END
GO

    根据传入的值，运行存储的 proc 返回不同的结果集@DogsOrCats

    EXEC dbo.DynamicResults 'Cat';

    回报：

    +------------+--------------+
| 动物类型 | 猫数 |
+------------+--------------+
| 猫 | 1 |
+------------+--------------+

    EXEC dbo.DynamicResults 'Dog';

    回报：

    +------------+--------------+
| 动物类型 | NumberOfDogs |
+------------+--------------+
| 狗 | 1 |
+------------+--------------+
    • 3

相关问题