主页 / dba / 问题 / 5863
Accepted
Delux
Asked: 2011-09-17 06:59:57 +0800 CST

附加数据库触发器

  • 772

当有人在服务器级别进行更改（例如附加或创建数据库）时，是否可以编写触发器？我有一个开发服务器，任何人都可以在其中添加产品数据库的副本以进行测试，但没有清理程序。我想在添加数据库时添加以下扩展属性。

EXEC sys.sp_addextendedproperty 
@name = N'Owner', 
@value = N'Username';

EXEC sys.sp_addextendedproperty 
@name = N'StartDate', 
@value = N'9/1/2011';
sql-server-2008

1 个回答

  1. Best Answer

    您可以为此使用DDL 触发器。似乎没有为附加引发DDL 事件，但肯定有 CREATE DATABASE。您可以通过拒绝对 sp_attachdb 的权限并强制每个人改为使用 CREATE DATABASE FOR ATTACH 来解决此问题。

    下面的示例感觉有点像 hack，因此希望具有更多 DDL 触发器经验的人会提出一种更简洁的方法来执行此操作。

    IF EXISTS (SELECT NULL FROM sys.server_triggers WHERE name = 'ddl_trig_database')
BEGIN
    DROP TRIGGER ddl_trig_database
    ON ALL SERVER;
END
GO

CREATE TRIGGER ddl_trig_database 
ON ALL SERVER 
FOR CREATE_DATABASE 
AS 
    DECLARE 
        @DatabaseName NVARCHAR(128)
        , @CreatedBy NVARCHAR(128)
        , @CreatedDate NVARCHAR(23)
        , @SQL NVARCHAR(4000);

    SELECT 
        @DatabaseName = EVENTDATA().value('(/EVENT_INSTANCE/DatabaseName)[1]','NVARCHAR(128)')
        , @CreatedBy = EVENTDATA().value('(/EVENT_INSTANCE/LoginName)[1]','NVARCHAR(128)')
        , @CreatedDate = EVENTDATA().value('(/EVENT_INSTANCE/PostTime)[1]','NVARCHAR(23)');

    SET @SQL = '
        USE ' + @DatabaseName + ';
        EXEC sys.sp_addextendedproperty @name = N''Owner'', @value = N''' + @CreatedBy + ''';
        EXEC sys.sp_addextendedproperty @name = N''StartDate'', @value = N''' + @CreatedDate + ''';';

    -- PRINT @SQL;
    EXEC (@SQL);

GO

CREATE DATABASE MyTestDatabase;
GO

DROP TRIGGER ddl_trig_database
ON ALL SERVER;
GO

DROP DATABASE MyTestDatabase;
GO
    • 4

相关问题