主页 / dba / 问题 / 310044
Accepted
xhr489
Asked: 2022-03-23 13:59:51 +0800 CST

事务日志中的日志记录

  • 772

事务日志中数据修改的日志记录：是只包含受影响的行和列的前后状态还是包含所有列（受影响的行）的前后状态，即日志记录包含整行还是仅包含被修改的行的一部分？

谢谢

编辑：我现在创建了一个实验，似乎表中的列数不会影响数据修改的事务日志的大小，即如果我col2在表中更新，那么表是否有 5 列或100 列，事务日志的增长将是相同的。

sql-server transaction-log

2 个回答

  1. Best Answer

    扩展 Tibor Karaszi 在评论部分提到的许多其他因素。我写了一些演示代码，只显示了三个场景。您已经可以看到日志记录数量、长度和内容的差异。我确实在解释每个测试之间添加了评论。

    描述列将让您对日志记录的内容有一个很好的了解。

    如果您想查看RowLog Contents X列的内容，请参阅这篇文章。

    USE master;
GO
DECLARE @SQL nvarchar(1000);

IF EXISTS (SELECT 1 FROM sys.databases WHERE [name] = N'LogRecordMod')
  BEGIN
    SET @SQL = 
      N'USE [master];
       ALTER DATABASE LogRecordMod SET SINGLE_USER WITH ROLLBACK IMMEDIATE;
       USE [master];
       DROP DATABASE LogRecordMod;';
    EXEC (@SQL);
  END;
ELSE
  BEGIN
    PRINT 'Database does not exist'
  END;
GO

CREATE DATABASE LogRecordMod;
GO

/*
Change settings to reduce the number of log records
*/
USE master;
GO
ALTER DATABASE LogRecordMod SET RECOVERY SIMPLE;
GO
ALTER DATABASE LogRecordMod SET AUTO_CREATE_STATISTICS OFF;
GO

/*
Create a table
Insert data
*/
USE LogRecordMod;
GO
DROP TABLE IF EXISTS dbo.testMod;
GO
CREATE TABLE dbo.testMod (
  ProductID integer,
  StoreID integer,
  Timestamp DATETIME DEFAULT CURRENT_TIMESTAMP,
  CONSTRAINT PK_testMod_ProductID PRIMARY KEY CLUSTERED (ProductID)
);

CREATE NONCLUSTERED INDEX IX_testMod_StoreID
  ON dbo.testMod (StoreID);   
GO  

INSERT INTO dbo.testMod (ProductID, StoreID) VALUES 
  (1,1001),
  (2,1002),
  (3,1003),
  (4,1004),
  (5,1005),
  (6,1006);
GO

CHECKPOINT;
GO

--Test one: modify primary key
BEGIN TRAN;
GO
UPDATE dbo.testMod SET ProductID = 7
WHERE ProductID = 1;
GO
CHECKPOINT;
GO
--check the log record generated due to a change in primary key
--You can ignore the last four records, those are related to checkpoint and not the update statement
SELECT * FROM fn_dblog (NULL, NULL);
GO
--once you examined the log records, run this 
COMMIT TRAN;
GO
CHECKPOINT;
GO
SELECT * FROM fn_dblog (NULL, NULL);
GO

--Test two: modify a column with non-clustered index
BEGIN TRAN;
GO
UPDATE dbo.testMod SET StoreID = 1007
WHERE ProductID = 7;
GO
CHECKPOINT;
GO
--check the log record generated due to a change in primary key
--You can ignore the last four records, those are related to checkpoint and not the update statement
SELECT * FROM fn_dblog (NULL, NULL);
GO
--once you examined the log records, run this 
COMMIT TRAN;
GO
CHECKPOINT;
GO
SELECT * FROM fn_dblog (NULL, NULL);
GO

--Test three: modify a column not part of any index
BEGIN TRAN;
GO
UPDATE dbo.testMod SET Timestamp = GETDATE()-7
WHERE ProductID = 7;
GO
CHECKPOINT;
GO
--check the log record generated due to a change in primary key
--You can ignore the last four records, those are related to checkpoint and not the update statement
SELECT * FROM fn_dblog (NULL, NULL);
GO
--once you examined the log records, run this 
COMMIT TRAN;
GO
CHECKPOINT;
GO
SELECT * FROM fn_dblog (NULL, NULL);
GO

/*
Clean up
Drop the database
*/
USE master;
GO
DROP DATABASE IF EXISTS LogRecordMod;
GO
    • 2

  2. 事务日志记录所有事务以及每个事务所做的数据库修改。更新未触及的列不计算在内。它记录页面更改。这是关于页面而不是记录。

    没有previuos 页面版本。previuos 页面版本存储在完整的数据库备份中。然后应用 tlog 中的每个页面更改，您可以在完全恢复后滚动完成所有事务。

    还记录回滚操作。每个事务都会在事务日志上保留空间，以确保存在足够的日志空间来支持由显式回滚语句或遇到错误导致的回滚。保留的空间量取决于事务中执行的操作，但通常等于用于记录每个操作的空间量。当事务完成时，该保留空间被释放。

    • 0

相关问题