主页 / dba / 问题 / 222883
Accepted
egor7
Asked: 2018-11-20 05:40:29 +0800 CST

如何在对列有约束的表中插入数据？- 在并行查询中

  • 772

我有一个 Oracle 数据库，其中包含一个包含唯一字段的表：

create table t(n number, CONSTRAINT n_unq UNIQUE (n));

然后从 session-1 有人试图插入一些数据：

insert into t(n) values(1);
-- no commit yet

在 session-2 中有人试图做同样的事情：

insert into t(n) values(1);
-- hangs here, wating for commit/rollback in session-1

克服这种遗憾情况的正确方法是什么？Session-2 似乎被困住了，它可能会被 session-1 挂起很长一段时间“被捕获”。

我知道序列的方式，但是如果任务更复杂怎么办，比如说：编写一个函数来检查值是否存在并返回它，如果不存在则插入（这是刚刚引入的陷阱，当运行并行相同的代码）然后返回它。

-- Ex:
create or replace function f(pn number) return number
is
  pret number;
begin
  select n into pret from t where n = pn;
  return pret;
exception when no_data_found then
  insert into t(n) values (pn);
  -- hangs here in parallel calls f(<new_value>)
  return pn;
end;
oracle insert

1 个回答

  1. Best Answer

    尽快提交。否则，只是给你一个想法：

    create table t(n number, CONSTRAINT n_unq UNIQUE (n));

create or replace function f(pn number) return number
is
  pret number;
  l_ret number;
begin
  select n into pret from t where n = pn;
  return pret;
exception when no_data_found then
  l_ret := dbms_lock.request(id => pn, timeout => 0, release_on_commit => true);
  dbms_output.put_line('lock return code: ' || l_ret);
  if l_ret = 0 then 
    insert into t(n) values (pn);
    return pn;
  else
    return -1; -- can not insert
  end if;
end;
/

    第 1 节：

    set serveroutput on
declare
  l_ret number;
begin
  l_ret := f(1);
  dbms_output.put_line('f return code: ' || l_ret);
end;
/

lock return code: 0
f return code: 1

select * from t;

         N
----------
         1

    第 2 节：

    set serveroutput on
declare
  l_ret number;
begin
  l_ret := f(1);
  dbms_output.put_line('f return code: ' || l_ret);
end;
/

lock return code: 1
f return code: -1

select * from t;

no rows selected

    第 1 节：

    commit;

    第 2 节：

    select * from t;

         N
----------
         1

set serveroutput on
declare
  l_ret number;
begin
  l_ret := f(1);
  dbms_output.put_line('f return code: ' || l_ret);
end;
/

f return code: 1

    我不确定这是否真的对您有帮助，理想的解决方案是防止多个会话试图在长事务中插入相同的值。

    • 1

相关问题