主页 / dba / 问题 / 175411
Accepted
Malvineous
Asked: 2017-06-06 01:12:21 +0800 CST

CONVERT() 在 Oracle 中返回带有 CLOB 的垃圾

  • 772

我正在寻找修复 Oracle 中的数据表，最好是通过非特权 SQL，该 SQL 已将 UTF-8 数据插入到 UTF-8 数据库中，错误地使用了 Latin-1 字符集。

该符号β GREEK SMALL LETTER BETA应该已经进入数据库，但是这两个字符β已经进入......因为两个 UTF-8 字符 Î LATIN CAPITAL LETTER I WITH CIRCUMFLEX后跟² SUPERSCRIPT TWO.

此示例代码演示了问题和修复，但它仅适用于VARCHAR列。一旦CLOB使用 a ，转换就会失败：

-- This must return AL32UTF8 for this example to be valid
SELECT VALUE FROM NLS_DATABASE_PARAMETERS WHERE PARAMETER='NLS_CHARACTERSET';

CREATE TABLE EXAMPLE (T VARCHAR2(20));
INSERT INTO EXAMPLE (T) VALUES ('Example β');
SELECT T FROM EXAMPLE; -- Should return 'Example β'
SELECT CONVERT(T, 'WE8ISO8859P1') FROM EXAMPLE;
UPDATE EXAMPLE SET T=CONVERT(T, 'WE8ISO8859P1');
SELECT T FROM EXAMPLE; -- Should return 'Example β', problem fixed
DROP TABLE EXAMPLE;

但是，如果将VARCHAR2(20)其更改为CLOB则不再有效。 CONVERT()返回垃圾字符。我可以TO_CHAR()用来解决这个问题，但最终我得到一个错误，它CLOB超过 4000 个字符，所以TO_CHAR()失败了。

CLOB当使用超过 4000 个字符的列时，有没有办法让上述示例正常工作？

oracle character-set

1 个回答

  1. Best Answer

    DBMS_LOB包也有转换功能。不幸的是，不支持将 CLOB 转换为 CLOB 并一步更改字符集，因此数据首先转换为 BLOB，然后再转换回 CLOB。

    CREATE TABLE EXAMPLE (T CLOB);
INSERT INTO EXAMPLE (T) VALUES ('Example β ');

begin
  for i in 1..12
  loop
    update example set t = t || t;
  end loop;
  commit;
end;
/

select dbms_lob.getlength(t) from example;

DBMS_LOB.GETLENGTH(T)
---------------------
                45056

    现在转换部分：

    create or replace function repair_data (p_clob clob) return clob as
  l_blob blob; 
  l_dest_offset number := 1;
  l_src_offset number := 1;
  l_lang_context number := 0;
  l_warning number;
  l_result clob;
begin
  dbms_lob.createtemporary(l_blob, true, dbms_lob.call);
  dbms_lob.createtemporary(l_result, true, dbms_lob.call);
  dbms_lob.converttoblob(l_blob, p_clob, dbms_lob.lobmaxsize, l_dest_offset, l_src_offset,
                         nls_charset_id('WE8ISO8859P1'), l_lang_context, l_warning);
  l_dest_offset := 1;
  l_src_offset := 1;
  l_lang_context := 0;
  dbms_lob.converttoclob(l_result, l_blob, dbms_lob.lobmaxsize, l_dest_offset, l_src_offset,
                         nls_charset_id('AL32UTF8'), l_lang_context, l_warning);
  return l_result;
end;
/

select repair_data(T) from example;

REPAIR_DATA(T)                          
----------------------------- 
Example β Example β Example β ...

update example set t = repair_data(t);
...
    • 5

相关问题