主页 / dba / 问题 / 131247
Accepted
jpmc26
Asked: 2016-03-04 19:05:32 +0800 CST

确定out游标的结构

  • 772

我在 Oracle 中有一个函数，我和我的团队都没有写过，而且被严重混淆了。但是，它有一个游标输出参数。如何找出游标包含的数字和类型？

有关我需要的示例，请考虑此游标：

DECLARE
  TEMP1 VARCHAR2(500);
  TEMP2 NUMBER;
  TEMP3 RAW(16);
  TEMP SYS_REFCURSOR;
  PROCEDURE MAKE_TEMP(TEMP_RETURN OUT SYS_REFCURSOR) IS
  BEGIN
    OPEN TEMP_RETURN FOR SELECT DUMMY, 5, HEXTORAW('111') FROM DUAL;
  END;
BEGIN
  MAKE_TEMP(TEMP);
  LOOP
    FETCH TEMP INTO TEMP1, TEMP2, TEMP3;
    EXIT WHEN (TEMP%NOTFOUND);
    DBMS_OUTPUT.PUT_LINE('1: '||TEMP1);
    DBMS_OUTPUT.PUT_LINE('2: '||TO_CHAR(TEMP2));
    DBMS_OUTPUT.PUT_LINE('3: '||RAWTOHEX(TEMP3));
  END LOOP;
  CLOSE TEMP;
END;
/

如果MAKE_TEMP是我尝试使用的函数，我需要知道它每行有 3 个值，并且这些值按顺序是 a VARCHAR2、 aNUMBER和 a RAW，这样我就可以定义变量来保存结果。

我正在使用 Oracle 11.2.0.1.0，但如果也存在更新版本的答案，我将不胜感激。

为什么我不能只看源码

如果您必须知道，该函数是 Oracle ASP.NET Membership Provider 的一部分，并且是由 Oracle 编写的。我正在尝试调试一个问题，想看看这个函数返回了什么。该函数的源代码是这样开始的：

create or replace 
FUNCTION  "ORA_ASPNET_MEM_GETALLUSERS" wrapped
0
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
abcd
3
8
9200000
1
4
0
33

如您所见，（充其量）提取有关该光标的任何信息将极其困难。

oracle oracle-11g-r2

1 个回答

  1. Best Answer

    此示例代码展示了如何解析一个ref_cursor. 还有其他可用的列，请参阅 的定义以SYS.DBMS_SQL.desc_tab2获取可用列的完整列表。

    在此示例中，我ref_cursor的定义为select * from user_tables. 您当然会用自己的ref_cursor.

    DECLARE
   l_csrid       INTEGER;
   l_coldesc     SYS.DBMS_SQL.desc_tab2;
   l_colcnt      INTEGER;
   l_refcursor   SYS_REFCURSOR;

   FUNCTION tostring (p_label   IN VARCHAR2
                     , p_value   IN VARCHAR2)
      RETURN VARCHAR2
   AS
   BEGIN
      RETURN RPAD (p_label, 30)
             || ': '
             || p_value
             || UTL_TCP.crlf;
   END tostring;

   PROCEDURE myput_line (p_rec      IN DBMS_SQL.desc_rec2
                       , p_colnum   IN INTEGER)
   AS
   BEGIN
      DBMS_OUTPUT.put_line (   RPAD ('_', 30, '_') 
                        || UTL_TCP.crlf
                        || tostring (p_label => 'Column'
                                   , p_value => p_colnum)
                        || tostring (p_label => 'Name'
                                   , p_value => p_rec.col_name)
                        || tostring (p_label => 'Type'
                                   , p_value => p_rec.col_type)
                        || tostring (p_label => 'Null OK'
                                   , p_value => CASE WHEN p_rec.col_null_ok
                                                     THEN 'Yes' 
                                                     ELSE 'No' 
                                                END));
   END myput_line;
 BEGIN
   OPEN l_refcursor FOR
      SELECT * FROM user_tables;

   l_csrid   := DBMS_SQL.to_cursor_number (rc => l_refcursor);
   DBMS_SQL.describe_columns2 (c       => l_csrid
                             , col_cnt => l_colcnt
                             , desc_t  => l_coldesc);

   FOR i IN 1 .. l_colcnt LOOP
      myput_line (l_coldesc (i), i);
   END LOOP;
END;
    • 3

相关问题