主页 / computer / 问题 / 1887138
Accepted
Mauro
Asked: 2025-03-19 02:01:12 +0800 CST

如何在 Excel 2019 中使用空白单元格计算最后 N 行的平均值

  • 772

我正在尝试计算 Excel 中最后 N 行的平均值，但我有一些空白（和合并）单元格；如下所示：

例子

一个
1
2
十
3
4
5
6
7
是
8
9
10

例如，要计算最后四行的平均值，应该计算 A8 到 A12 的平均值而忽略 A9，因为 A9 不是一个数字。

此外，还会添加新行，因此平均值需要动态，始终取最后 N 个编译的带有数字的行。

我发现了一些关于这个主题的类似文章，但它们都假设连续数据，而没有解决数据中某些空白/文本单元格的情况；这个答案似乎解决了这个问题，但我无法让这些公式为我工作（我不确定如何在接受的答案中使用它，因为它使用了多列，而我只有一列）。

这和这似乎也相关，但是在我的案例中我还是无法让它们发挥作用。

有办法吗？

microsoft-excel

4 个回答

  1. Best Answer

    您可以在Excel 2019中尝试以下方法：

    =AVERAGE(
         INDEX(A:A,
         AGGREGATE(14,7,ROW(A:A)/((ISNUMBER(A:A))*(A:A<>"")),4)):
         INDEX(A:A,
         MATCH(2,1/((ISNUMBER(A:A))*(A:A<>""))))
 )

    解释：

    • 以下查找最后一个数值的单元格位置
    =MATCH(2,1/((ISNUMBER(A:A))*(A:A<>"")))
    • 现在，包装内INDEX()会给我们指定行号的单元格值。
    • 以下返回具有值的第四大行号
    =AGGREGATE(14,7,ROW(A:A)/((ISNUMBER(A:A))*(A:A<>"")),4)
    • 类似地，包装内INDEX()将产生该特定行的单元格值。
    • 使用完整查找，然后使用冒号，然后进行另一次完整查找会给 Excel 所需的提示，即它必须返回一个引用。
    • 因此，它会对所定位的两个单元格的范围进行划分，并将其传递给AVERAGE()函数，包围其他所有内容，以返回所需的输出。
    • 另请注意，根据个人的 Excel 版本，可能需要在退出编辑模式时按CTRL+ SHIFT+ 。ENTER

    也许使用MS365：

    =AVERAGE(TAKE(FILTER(A:A,(ISNUMBER(A:A)*(A:A<>"")),""),-4))
    • 3 
  2. =AVERAGE(
    INDEX(
        $A:$A,
        LARGE(
            ISNUMBER($A$1:INDEX($A:$A, LOOKUP(2, 1 / $A:$A, ROW($A:$A)))) *
                ROW($A$1:INDEX($A:$A, LOOKUP(2, 1 / $A:$A, ROW($A:$A)))),
            {1; 2; 3; 4}
        )
    )
)
    • LOOKUP(2,1/A:A,ROW(A:A))返回包含数字的最后一个单元格的行号（此函数将忽略错误）。
    • 然后我们用它INDEX创建一个值数组
    • 测试它们看看哪些是数字
    • 仅返回数字值的行号
    • 与数组参数一起使用LARGE以返回最高四行数字{1;2;3;4}
    • 在外部函数中使用这些行号INDEX来返回这些行中包含的值
    • AVERAGE这四个数字。

    当然，365你也可以使用更短的：

    =AVERAGE(TAKE(FILTER(A:A,ISNUMBER(A:A)),-4))
    • 1

  3. 您可以在 Excel 365 中使用此公式来实现您的目标：
    =AVERAGE(TAKE(FILTER(A1:A12,ISNUMBER(A1:A12)),-4))

    • FILTER(A1:A12,ISNUMBER(A1:A12))- 删除非数字值
    • TAKE(FILTER(...),-4))- 保留最后四位数字
    • =AVERAGE(...)- 计算平均值

    在此处输入图片描述

    • 1

  4. 另一种选择： =AVERAGE(INDEX(A:A,MATCH(2,1/A:A)-{3,2,1,0}))

    或者在 M365 中： =AVERAGE(TAKE(A:.A,-4))

    （平均值忽略非数值）

    • 0

相关问题