主页 / computer / 问题 / 1880739
Accepted
Dominique
Asked: 2025-02-18 15:47:59 +0800 CST

如何将 Excel 中的 2x512 数组转换为 32x32 数组

  • 772

我有很多信息，如下所示：

 0   1   2   3  4  ...
'0 'C1 '81 '40 '1  ...

（供您参考：第二行包含十六进制数，我使用它是'为了使 Excel 避免将'12（即 18，十八）这样的值转换为 12（十二）。

我知道函数，例如=ToRow()和=ToCol()可以将数据转换为单行或单列。我还知道函数，例如=Sequence()可以创建二维矩阵，但我找不到ToMatrix()或ToArray()函数。

有人知道在 Excel-365 中执行此操作的简单方法吗？

提前致谢

microsoft-excel

4 个回答

  1. 您可以使用 lambda 函数来实现：

    转到公式/名称管理器/新建并输入：

    • 姓名v_stack
    • 指：=LAMBDA(rng,cols,rows,IF(COLUMNS(rng)>cols,VSTACK(TAKE(rng,rows,cols),v_stack(DROP(rng,0,cols),cols,rows)),rng))

    新名称形式

    现在你有一个接受三个参数的“v_stack”函数

    • 想要转换的范围的地址
    • 要切分的列数
    • 原始范围内的行数

    分解公式：

    =LAMBDA(rng,cols,rows,
 IF(
   COLUMNS(rng)>cols,
   VSTACK(
     TAKE(rng,rows,cols),
     v_stack(DROP(rng,0,cols),cols,rows)),
   rng))

    函数使用示例

    • 6

  2. 不确定这是否是您期望的顺序： =WRAPROWS(TOCOL(A1:SR2,,1),32)

    荷兰语： =OMLOOP.RIJEN(NAAR.KOLOM(A1:SR2;;1);32)

    或者： =LET(a,A1:SR2,INDEX(a,1+MOD(SEQUENCE(32,,0),2),SEQUENCE(,32)+INT(SEQUENCE(32,,0,0.5))*32))

    荷兰语： =LET(a;A1:SR2;INDEX(a;1+REST(REEKS(32;;0);2),REEKS(;32)+GEHEEL(REEKS(32;;0;0,5))*32))

    • 4
  3. Best Answer

    根据这个技术社区的答案，虽然可能有一些更简单的事情：

    =LET(
    array, TRANSPOSE(A1:SR2),
    wrapcount, 32,
    totalRows, ROWS(array),
    groups, SEQUENCE(ROUNDUP(totalRows / wrapcount, 0), , 0),
    first, CHOOSEROWS(array, SEQUENCE(wrapcount)),
    TRANSPOSE(REDUCE(
        first,
        DROP(groups, 1),
        LAMBDA(a, b,
            HSTACK(
                a,
                CHOOSEROWS(
                    array,
                    SEQUENCE(
                        MIN(wrapcount, totalRows - b * wrapcount),
                        ,
                        b * wrapcount + 1
                    )))))))

    结果

    我唯一更改的是添加到TRANSPOSE()数组参数中，因为它们从 2 列而不是 2 行开始。并根据您的问题将包装计数更改为 32。然后对整个内容进行另一次转置。

    • 3 
  4. =LET(Array, $A$1:$SR$2, 
    Width, 32,
    topRows, WRAPROWS(CHOOSEROWS(Array,1), Width, ""),
    bottomRows, WRAPROWS(CHOOSEROWS(Array,2), Width, ""),
    order, SEQUENCE(QUOTIENT(COLUMNS(Array)-1, Width)+1),
    DROP(
        SORT(
            VSTACK(HSTACK(order, topRows),
                   HSTACK(order+0.5, bottomRows)),
        1),
    0, 1)
)

    这将把两行换行到指定的宽度，然后将两个结果交错。

    =LET(Array, $A$1:$SR$2,
    Width, 32,
    Height, 2*(1+QUOTIENT(COLUMNS(Array)-1,Width)),
    MAKEARRAY(Height, Width,
        LAMBDA(y, x,
            INDEX(Array,
                2-MOD(y, 2),
                1+MOD(x-1, Width)+Width*QUOTIENT(y-1, 2)
            )
        )
    )
)

    此版本只是通过依次扫描每个输出单元直接创建一个数组。

    • 0

相关问题