将月度数据合并到年初至今文件中时出现排序问题。使用查询，按天、时间和字母排序

根据您在评论中提到的这些假设：

1. 如果同一天对某个部件进行了两次测量，则假定它们的顺序正确，并被错误地命名
2. 如果同一天在 B、A 订单中有两个测量值，则假定它们的顺序不正确，但名称正确

你可以用这样的方法解决：

从附加的数据集开始：

添加索引列：

添加一个自定义列，为每一对连续的行分配一个 PaidID：

按 PairID 分组，将名为“Rows”的单列设置为“All Rows”：

然后编辑 Table.Group 定义，如查询所示：

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    ReType = Table.TransformColumnTypes(Source,{{"Date", type date}, {"Time", type time}, {"Letter", type text}, {"Data", type number}}),
    AddIndex = Table.AddIndexColumn(ReType, "Index", 0, 1, Int64.Type),
    AddPairID = Table.AddColumn(AddIndex, "PairID", each Number.RoundDown([Index]/2)),
    GroupRows = Table.Group(
        AddPairID, 
        {"PairID"}, 
        {
            {
                "Rows", 
                each 
                    let 
                        // This switches rows that are in the wrong order and keeps other rows in the same order
                        sorted = Table.Sort(_, {{"Letter", Order.Ascending}, {"Index", Order.Ascending}}),
                        // At this point A should be at pos 0 and B at pos 1 - if they're not, they are re-lettered
                        newLetter = Table.AddColumn(
                            sorted, 
                            "NewLetter", 
                            each if [Letter]="A" and Table.PositionOf(sorted,_)=1 then "B" else 
                                 if [Letter]="B" and Table.PositionOf(sorted,_)=0 then "A" else [Letter])
                    in newLetter
                    
            }
        }, 
        GroupKind.Local
    ),
    ExpandedRows = Table.ExpandTableColumn(GroupRows, "Rows", {"Date", "Time", "NewLetter", "Data"}, {"Date", "Time", "Letter", "Data"}),
    RemovePairID = Table.RemoveColumns(ExpandedRows,{"PairID"})
in
    RemovePairID

展开表格列（单击列顶部的双箭头），并确保公式栏如下所示：

最后删除 PairID 列：

Flex 有答案，但我的 Excel 不喜欢它，所以这是对我有用的修改版本

= let
Source = Excel.CurrentWorkbook(){[Name="Examples"]}[Content],
ReType = Table.TransformColumnTypes(#"Expanded Table Column1",{{"Source.Name", type text}, {"Date", type date}, {"Time", type time}, {"Letter", type text}, {"Data", type number}}),
SortTime = Table.Sort(ReType,{{"Date", Order.Ascending}, {"Time", Order.Ascending}}),
RemoveSource = Table.RemoveColumns(SortTime,{"Source.Name"}),
RemoveBlanks = Table.SelectRows(RemoveSource, each not List.IsEmpty(List.RemoveMatchingItems(Record.FieldValues(_), {"", null}))),
AddIndex = Table.AddIndexColumn(RemoveBlanks, "Index", 0, 1),
AddPairID = Table.AddColumn(AddIndex, "PairID", each Number.RoundDown([Index]/2)),
GroupRows = Table.Group(
    AddPairID, 
    {"PairID"}, 
    {
        {
            "Rows", 
            each 
                let 
                    // This switches rows that are in the wrong order and keeps other rows in the same order
                    sorted = Table.Sort(_, {{"Letter", Order.Ascending}, {"Index", Order.Ascending}}),
                    // At this point A should be at pos 0 and B at pos 1 - if they're not, they are re-lettered
                    newLetter = Table.AddColumn(
                        sorted, 
                        "NewLetter", 
                        each if [Letter]="A" and Table.PositionOf(sorted,_)=1 then "B" else 
                             if [Letter]="B" and Table.PositionOf(sorted,_)=0 then "A" else [Letter])
                in newLetter
                
        }
    }, 
    GroupKind.Local
),
ExpandedRows = Table.ExpandTableColumn(GroupRows, "Rows", {"Date", "Time", "NewLetter", "Data"}, {"Date", "Time", "Letter", "Data"}),
ReType2 = Table.TransformColumnTypes(ExpandedRows,{{"Date", type date}, {"Time", type time}, {"Letter", type text}, {"Data", type number}}),
RemovePairID = Table.RemoveColumns(ReType2,{"PairID"})
in
RemovePairID