主页 / computer / 问题 / 1857669
Accepted
CorlissExcelling
Asked: 2024-10-04 05:29:03 +0800 CST

如何使用自定义列排列对过滤函数进行排序，且排序时不包含标题？

  • 772

我能够让该公式适用于我有列AE和AF选择的过滤器。

当我尝试在公式中添加排序部分时，它将标题与其混合在一起，公式将标题与列出的数据混合在一起。

原来的：

=FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0)

按第一列升序排序：

=SORT(FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0),1,1)

有没有办法让标题不参与排序？

注意：数据集不是表格，我无法将其变成表格，因为客户不希望转换原始数据。

自定义列的资源：

更新：10/4/24 我尝试按照建议使用 DROP 部分，但出现了 NAME？错误，所以我的版本不允许我使用 DROP。——不过还是谢谢你。

microsoft-excel

2 个回答

  1. 尝试：

    SORT(DROP(FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0),1),1,1)
    • 1
  2. Best Answer

    由于根据 OP 的帖子，他们无权使用该DROP()功能，因此也可以使用以下公式来实现所需的输出：

    在此处输入图片描述

    =LET(
     _Vals, A:A,
     _LastRow, MATCH(2,1/(_Vals<>"")),
     _Nvals, A2:INDEX(_Vals,_LastRow),
     _Name, F2:INDEX(F:F,_LastRow),
     SORT(FILTER(CHOOSE({1,2},_Name,_Nvals),_Nvals>0)))

    因此，就每个 OP 的范围而言：

    =LET(
     _A, AE:AE,
     _LastRow, MATCH(2,1/(_A<>"")),
     _NA, AE2:INDEX(_A,_LastRow),
     _B, AF2:INDEX(AF:AF,_LastRow),
     SORT(FILTER(CHOOSE({1,2},_B,_A),_A>0)))

    AE请注意，上述公式以最后一个非空单元格作为所有其他列的最后一行基准。

    或者，也可以使用类似这样的方法：

    =LET(
     a, FILTER(CHOOSE({1,2},AF:AF,AE:AE),AE:AE>0),
     SORT(INDEX(a, SEQUENCE(ROWS(a)-1,,2),{1,2})))

    在此处输入图片描述

    • 0

相关问题