主页 / computer / 问题 / 1849722
Accepted
user194860
Asked: 2024-07-21 01:26:38 +0800 CST

Nushell：首先列出目录，包括目录的符号链接

  • 772

使用Nushell ，我希望ls在文件之前列出目录。此外，我希望符号链接正确排序：如果它是指向目录的链接，则应将其包含在目录列表中。如果它是指向文件的链接，则应将其包含在文件列表中。

我开发了以下脚本：

let is_dir = {|file|
    $file.type == 'dir' or ($file.target | to text | str ends-with '/')
};

let dirs = ls --all --long
    | filter $is_dir
    | sort-by name --ignore-case;

let files = ls --all --long
    | filter {|file| not (do $is_dir $file)}
    | sort-by name --ignore-case;

$dirs ++ $files
    | select name

但对于如此简单的请求来说，这似乎太多了。

  1. 代码能不能简化一点？
    1.1 有没有更好的方法可以确定符号链接是否指向目录？使用$file.target | to text | str ends-with '/')是我看到的唯一方法，但我对这个解决方案并不满意。1.2
    另外，filter {|file| not (do $is_dir $file)}这不是我写过的最好的代码。我怎样才能做得更好？
  2. 有没有更好的方法来实现同样的目的？

这个问题是关于Nushell 的，而不是其他 shell 的。:-)

symbolic-link

1 个回答

  1. Best Answer

    请注意，上面的代码中存在一些潜在问题。我说“潜在”，是因为如果它对你有用，也许你的用例不会触发这些问题。

    • 目录的符号链接目标不一定以 结尾/。它仅取决于创建符号链接时是否使用了尾随斜杠。 ls -l /可以看到默认的 Linux（至少在 Ubuntu 上）符号链接目标不包含尾随斜杠。

    • Nushell ls（像普通的/usr/bin/ls或甚至eza）不会解析符号链接到符号链接（或进一步嵌套）的“最终”目标。我想不出一种“简单”的内置 Nushell 方法（除了递归技术）来解析最终目标，但您始终可以选择realpath在非 Windows 平台上使用。

    • 据我所知，您的实现仅在当前目录中运行时才有效。尝试在其他路径上使用它ls <path>可能不会成功，因为$file.target不会返回完全限定的路径。

    考虑到这些“限制”，下面是一个更紧凑的版本，但也有同样的问题。它在表中插入一个新列，其中ls包含目标（或实际文件/目录）的类型，并根据该类型对结果进行排序。

    ls -l
| insert sort-type {|f|
    match $f.type {
      # For symlinks, use the type of the target
      symlink => ( ls -D $f.target | get type.0 )
      # Otherwise just use the type:
      _ => $f.type
    }
  }
| sort-by sort-type name
| reject sort-type

    稍微更强大的版本可以从另一个目录使用ls -l <path>：

    ls -l
| insert sort-type {|f|
    match $f.type {
      symlink => {
        $f.name | path parse | get parent
        | path join $f.target
        | ls -D $in | get type.0
      }
      _ => $f.type
    }
  }
| sort-by sort-type name

    最后，如果您愿意使用非 Nushell 命令（realpath），您将获得一个紧凑的版本，处理嵌套的符号链接，并在当前目录之外工作：

    ls -l
| insert sort-type {|f|
    match $f.type {
      symlink => ( realpath $f.name | ls -D $in | get type.0 )
      _ => $f.type
    }
  }
| sort-by sort-type name
| reject sort-type

    请注意，有一个PR 正在进行中以允许闭包sort-by，这将增加额外的实现可能性，但我不确定这是否比上述选项更容易。

    • 1

相关问题