主页 / computer / 问题 / 1849082
Accepted
Chris
Asked: 2024-07-15 05:52:39 +0800 CST

在 Microsoft Word 中，如何从不同的文档（而不是同一文档内的不同部分）继续页码

  • 772

是否可以继续前一个文档的页码，而无需手动调整起始页码？我还总是想确保第二个文档从偶数页码开始。示例：

我们将第一个文档命名为 ABC.doc，将第二个文档命名为 123.doc。这是两个独立的物理 Word 文件。假设文档 ABC 有 1-14 页。那么文档 123 将从偶数页 16 开始。如果我更新了文档 ABC，现在有 15 页，文档 123 仍将从第 16 页开始。但是，如果我更新了文档 ABC，现在有 16 页，那么文档 123 也将自动更新并从第 18 页开始。同样，如果我从文档 ABC 中删除一两页，使其在第 12 页结束，那么文档 123 将再次自动更新并从第 14 页开始。

我有几个文档，如果可能的话，我希望这个功能能够用于这些文档，即从上一个文档结束的地方继续下一个文档的列表。我意识到，只有打开文档本身，页面才会更新。但是，这可能吗？是的，我知道我可以偏移每个文档的第一页，因此我可以手动编辑第一页的页码，但我想知道文档本身是否可以在每次打开时自动更新。

谢谢。

microsoft-word

1 个回答

  1. Best Answer

    请查看我在 Microsoft Answers 网站上的文章：使用 RD 和其他字段

    （https://answers.microsoft.com/en-us/msoffice/forum/all/using-rd-and-other-fields-to-construct-multi-file/f1c8cd3c-c92d-4dc3-bfb7-84773c8b4dce）

    它大量引用了乔纳森·韦斯特 (Jonathan West) 的一篇文章的档案副本。

    不幸的是，可能发生的情况是，每个文档的页码都从第 1 页开始，因此目录看起来非常混乱，每个文档的页码都从头开始。您可能希望整个文档的页面都是连续编号的。如果包括目录的封面文件有 5 页，那么您希望 chapter1.doc 从第 6 页开始。

    手动执行此操作很麻烦，但如果您没有太多单独的文件，则可以做到。打开 chapter1.doc，然后转到插入/页码。将出现以下对话框。

    页码对话框的图像。

    单击“格式”按钮，将出现以下对话框。

    页码格式对话框的图像，它是页码对话框的扩展，显示了选择继续上一节的选项。

    单击“起始于”按钮，在右侧的框中输入 6（或您想要的起始页码），然后单击“确定”关闭对话框。页码对话框将更改为现在的样子。（注意：取消按钮现在是关闭按钮。）

    再次显示页码对话框的图像，现在显示取消按钮已更改为关闭按钮。

    单击“关闭”以清除对话框。不要单击“确定”，因为这会将页码插入页眉。我假设页码已经存在，您不需要另一组！

    现在您需要移至文档末尾以找出最后一页的页码。记下来，您将需要它来设置下一章的起始页。现在保存并关闭 chapter1.doc。

    然后打开 Chapter2.doc 并重复整个过程，将当前章节最后一页的页码加 1，以设置下一章的起始页。浏览完所有章节后，您可以再次更新目录，只要您没有犯任何错误，目录中的页码就会全部对齐。

    如您所见，如果您的文档集中有超过 2 或 3 个文档，那么这个过程会有些费力。幸运的是，这个过程非常适合自动化；为了让您的生活更轻松，我编写了执行此操作的宏。（如果您想下载并直接将其导入模板，此代码也在 TechTrax 库中。）

    Sub UpdateTocAndPageNumbers()
Dim oField As Field
Dim strCode As String
Dim iLastPage As Long
Dim oDoc As Document

ChDir ActiveDocument.Path
With ActiveDocument.ActiveWindow.View
    .ShowAll = False
    .ShowHiddenText = False
    .ShowFieldCodes = False
    .Type = wdPrintView
End With
ActiveDocument.Repaginate
Selection.Move unit:=wdStory, Count:=1
iLastPage = Selection.Information(wdActiveEndAdjustedPageNumber)

For Each oField In ActiveDocument.Fields
    If oField.Type = wdFieldRefDoc Then
        strCode = Trim$(oField.Code)
        strCode = Trim$(Mid$(strCode, InStr(strCode, " ")))
        If LCase$(Left$(strCode, 2)) = "\f" Then
            strCode = Trim$(Mid$(strCode, 3))
        End If
        If LCase$(Right$(strCode, 2)) = "\f" Then
            strCode = Trim$(Left$(strCode, Len(strCode) - 2))
        End If
        If Asc(strCode) = 34 Then
            strCode = Trim$(Mid$(strCode, 2, Len(strCode) - 2))
        End If

        ChDir ActiveDocument.Path
        Set oDoc = Documents.Open(FileName:=strCode)
        oDoc.Activate
        With oDoc.ActiveWindow.View
            .ShowAll = False
            .ShowHiddenText = False
            .ShowFieldCodes = False
            .Type = wdPrintView
        End With
        oDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
                 PageNumbers.RestartNumberingAtSection = True
        oDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
                 PageNumbers.StartingNumber = iLastPage + 1
        oDoc.Repaginate
        Selection.Move unit:=wdStory, Count:=1
        iLastPage = Selection.Information(wdActiveEndAdjustedPageNumber)
        oDoc.Close SaveChanges:=wdSaveChanges
    End If
Next oField
ChDir ActiveDocument.Path
ActiveDocument.Fields.Update
End Sub

    当您的封面文档打开时，运行此宏。它会执行以下操作：

    设置文档，使隐藏文本和字段代码不显示。这可确保屏幕上显示的页码与要打印的页码相匹配。

    重新对封面文档进行分页，并找出最后一页的页码。

    依次查找每个 RD 字段。对于每个字段，它执行以下操作：a. 打开相关文档，b. 将起始页设置为适当的值，c. 重新分页文档，d. 找出最后一页的页码，e. 保存并关闭文档。处理完所有 RD 字段后，它会更新封面文档中的字段，包括目录。

    最初，您可能需要运行此宏两次。这是因为更新目录的过程可能会更改封面文档中的页数。

    宏甚至可以在 Word 97 中工作，因为在 Word 97 中 RD 字段选项中没有 \f 开关。如果是这种情况，则必须将该组的所有文档放在同一个文件夹中。无论如何，我建议您这样做

    • 2

相关问题