主页 / computer / 问题 / 1803641
Accepted
TrackerRick
Asked: 2023-08-11 23:38:19 +0800 CST

单个 SUMIFS 和 COUNTIFS 可以工作，但两个 SUMIFS 和两个 COUNTIFS 不起作用

  • 772

我正在导出制造环境的数据并将 CSV 导入 Excel。该数据每 5 分钟刷新一次。

在第一个工作表上，我能够使用单个 SUMIFS 和单个 COUNTIFS 正确计算效率％ (N:N)。但是，当我尝试添加两个 SUMIFS 并除以两个添加的 COUNTIFS 时，计算报告错误的结果。我应该补充一点，有时“HMP20 1”或“GHMP20 1”不存在。

此公式返回预期结果100.83：

=(SUMIFS('EP2P Mold Summary All Shifts'!N:N,
         'EP2P Mold Summary All Shifts'!B:B, "1",
         'EP2P Mold Summary All Shifts'!C:C, "GHMP20 1")/
 (COUNTIFS('EP2P Mold Summary All Shifts'!N:N, ">0",
         'EP2P Mold Summary All Shifts'!B:B, "1",
         'EP2P Mold Summary All Shifts'!C:C, "GHMP20 1")))

此计算返回错误结果388.61：：

=(SUMIFS('EP2P Mold Summary All Shifts'!N:N,
         'EP2P Mold Summary All Shifts'!B:B, "1",
         'EP2P Mold Summary All Shifts'!C:C,"HMP20 1")+
  SUMIFS('EP2P Mold Summary All Shifts'!N:N,
         'EP2P Mold Summary All Shifts'!B:B, "1",
         'EP2P Mold Summary All Shifts'!C:C, "GHMP20 1")/
 (COUNTIFS('EP2P Mold Summary All Shifts'!N:N, ">0",
         'EP2P Mold Summary All Shifts'!B:B, "1",
         'EP2P Mold Summary All Shifts'!C:C, "HMP20 1")+
  COUNTIFS('EP2P Mold Summary All Shifts'!N:N, ">0",
         'EP2P Mold Summary All Shifts'!B:B, "1",
         'EP2P Mold Summary All Shifts'!C:C, "GHMP20 1")))

样本数据

工作表： “EP2P 模具汇总所有班次”

乙      C 日-中 氮                                                                          
1 转移 机器 效率%
2 1 GHMP20 1 101
3 1 GHMP20 1 98
4 1 HMP20 1 112
5 3 HMP20 1 87
6 3 新东7 92
7 3 金信通7

数据工作表：“EP2P 模具汇总所有班次”
数据工作表：“EP2P 模具摘要所有班次

“结果工作表：“模具摘要所有班次”
Results Worksheet: "Mold Summary All Shifts"

microsoft-excel-365

1 个回答

  1. Best Answer

    可以使用AVERAGE 函数计算平均值

    FILTER 函数将根据条件返回数据的子集。

    进行这两项更改应该会使您更轻松地查看和扩展公式。

    1. 仅“GHMP20 1”

      ！-> 星号*相当于AND

          1a. IFERROR ： ""如果不匹配
    =IFERROR(
   AVERAGE(FILTER(N:N,(B:B=1)*
     (C:C="GHMP20 1"))),"")
          1b. 过滤器： 0如果没有匹配
    =AVERAGE(FILTER(N:N,(B:B=1)*
   (C:C="GHMP20 1"),0))

    2.“GHMP20 1”和“HMP20 1”

      ！-> 加号 + 相当于 OR

          2a. IFERROR ： ""如果不匹配
    =IFERROR(
   AVERAGE(FILTER(N:N,(B:B=1)*
     ((C:C="GHMP20 1")+(C:C="HMP20 1"))),"")
          2b. 过滤器： 0如果没有匹配
    =AVERAGE(FILTER(N:N,(B:B=1)*
   ((C:C="GHMP20 1")+(C:C="HMP20 1")),0))
    • 0

相关问题