在 Windows 中将快捷方式批量转换为相对快捷方式

我想出了一个快速的 VBScript 来批量更改快捷方式目标。它调用Relative.exe并覆盖现有的快捷方式，将目标更改为相对路径。

注意：在继续之前，请备份您的原始快捷方式。始终先使用示例文件进行测试。

（如果程序安装在不同的位置，请更新脚本第 9 行中的 Relative.exe 路径。）

Option Explicit
If WScript.Arguments.Count = 0  Then WScript.Quit
Dim WshShell, WshShortcut, sAppPath, oFSO, sCmd
Dim sSrcFile, sTarget, sArgs, sWStyle, sHotkey, sSkipped, i
Set WshShell = CreateObject ("WScript.Shell")
Set oFSO =  CreateObject ("Scripting.FileSystemObject")
sSkipped = "List of shortcuts skipped:" & vbCrLf  & vbCrLf

sAppPath = """" & "C:\Program Files (x86)\Relative\Relative.exe" & """"

For i = 0 To WScript.Arguments.Count - 1 
   sSrcFile = WScript.Arguments(i)   
   If LCase(Right(sSrcFile, 4)) <> ".lnk" Then Exit For
   
   'Get shortcut properties
   Set WshShortcut = WshShell.CreateShortcut(sSrcFile)
   sTarget = WshShortcut.TargetPath
   sWStyle = WshShortcut.WindowStyle
   sArgs = WshShortcut.Arguments
   sHotkey = WshShortcut.Hotkey
   
   'Skip if target has the .exe suffix, or the target is a File
   If InStr(sTarget, ".exe") > 0 Or oFSO.FileExists (sTarget) Then
      sTarget = ""
   End If

   'Skip if target is already in relative path format
   If InStr(sTarget, ".\") = 0 And Trim(sTarget) <> "" Then
      'Run Relative.exe and overwrite existing shortcut
      sCmd = sAppPath & " " & sTarget & " " & """" & _
        Replace(sSrcFile, ".lnk", "") & """"
      WshShell.Run sCmd,1, 1    
      
      'Restore shortcut Hotkey and Window style setting
      WScript.Sleep 500
      Set WshShortcut = WshShell.CreateShortcut(sSrcFile)
      WshShortcut.WindowStyle = sWStyle
      If sHotkey <> "" Then WshShortcut.Hotkey = sHotkey
      WshShortcut.Save
   Else
      sSkipped = sSkipped & sSrcFile & vbCrLf
   End If
   
Next

If Len (sSkipped) > 32 Then WScript.Echo sSkipped

指示

1. 将以上代码复制到记事本中，另存为ToRelative.vbs.
2. 打开您的Sendto文件夹（提示：shell:sendto在开始/运行中运行。）
3. 将脚本的快捷方式放在 SendTo 文件夹中。
4. 右键单击一组 .lnk 文件，单击发送到，然后 ToRelative在发送到菜单中进行选择。