主页 / computer / 问题 / 1664983
Accepted
RoyalGoose
Asked: 2021-07-28 05:59:11 +0800 CST

如何在 Excel 中插入值

  • 772

我有两张桌子。第一个包含特定天数的指示性条件利率（列标题）

日期 1天 7天 14天 30天 90 天
11.01.2021 4.36 4.36 4.30 4.49 4.64
12.01.2021 4.32 4.34 4.36 4.48 4.63
13.01.2021 4.25 4.32 4.34 4.43 4.60
14.01.2021 4.26 4.35 4.35 4.36 4.58
15.01.2021 4.33 4.35 4.37 4.34 4.57

第二个表，我需要在其中计算给定天数的实际费率

日期 天 速度
12.01.2021 21 ?
13.01.2021 74 ?
15.01.2021 40 ?

如您所见，某些日子给出了条件费率，而其他日子给出了实际费率。除其他事项外，每天都会给出有条件的利率，而实际利率仅在其中一些。我如何计算这个比率？例如，我在这里看到了线性插值的使用——如果实际天数是 21 天，那么最接近的条件利率是 14 天，我需要在未来几天推断这个值。我读到了=forecast，但它不能满足我的需要。Excel 中是否有可以帮助我执行此操作的函数，或者我是否需要为此编写 VBA 脚本？

microsoft-excel worksheet-function

2 个回答

  1. 我们需要得到设定点之间的天数的比率，并将该比率乘以上限和下限之间的差值，然后将下限添加到该结果中。

    必须执行的一个步骤是将标题更改为实际数字。

    在 OFFICE 365 中，我们可以使用 LET 来简化步骤：

    =LET(head,$B$1:$F$1,
         lkp,B7,
         rng,$B$2:$F$4,
         dt,$A$2:$A$4,
         rw,INDEX(rng,MATCH(A7,dt,0),0),
         mtch,MATCH(lkp,head),
         mtchp1,mtch+1,
         fst,INDEX(head,,mtch),
         scd,INDEX(head,,mtchp1),
         fct,(lkp-fst)/(scd-fst),
          vlue1,INDEX(rw,,mtch),
          vlue2,INDEX(rw,,mtchp1),
          (vlue2-vlue1)*fct+vlue1)

    在此处输入图像描述

    没有让：

    =(INDEX(INDEX($B$2:$F$4,MATCH(A7, $A$2:$A$4,0),0),, MATCH(B7, $B$1:$F$1)+1)- INDEX(INDEX($B$2:$F$4,MATCH(A7, $A$2:$A$4,0),0),, MATCH(B7, $B$1:$F$1)))* ((B7- INDEX($B$1:$F$1,, MATCH(B7, $B$1:$F$1)))/( INDEX($B$1:$F$1,, MATCH(B7, $B$1:$F$1)+1)- INDEX($B$1:$F$1,, MATCH(B7, $B$1:$F$1))))+ INDEX(INDEX($B$2:$F$4,MATCH(A7, $A$2:$A$4,0),0),, MATCH(B7, $B$1:$F$1))

    如您所见，它变得非常笨重且难以管理。

    在此处输入图像描述

    使用 LET 的另一种方法是在获取开始和结束 x 和 y 后使用 FORECAST.LINEAR 而不是数学来获得答案：

    =LET(head,$B$1:$F$1,
         lkp,B7,
         rng,$B$2:$F$4,
         dt,$A$2:$A$4,
         rw,INDEX(rng,MATCH(A7,dt,0),0),
         mtch,MATCH(lkp,head),
         mtchp1,mtch+1,
         fst,INDEX(head,,mtch),
         scd,INDEX(head,,mtchp1),
          vlue1,INDEX(rw,,mtch),
          vlue2,INDEX(rw,,mtchp1),
          FORECAST.LINEAR(lkp,CHOOSE({1,2},vlue1,vlue2),CHOOSE({1,2},fst,scd)))

    在此处输入图像描述

    • 3
  2. Best Answer

    在此处输入图像描述

    办公室 365：

    =FORECAST.LINEAR(B7,
 INDEX(B2:F2,MATCH(B7,$B$1:$F$1,1)):INDEX(B2:F2,MATCH(B7,$B$1:$F$1,1)+1),
 INDEX($B$1:$F$1,MATCH(B7,$B$1:$F$1,1)):INDEX($B$1:$F$1,MATCH(B7,$B$1:$F$1,1)+1))

    从Excel 插值

    令人惊讶的是，在 Excel 中很难进行线性插值。

    这使用 Excel 预测功能=FORECAST(x,known_y's,known_x's)。

    =INDEX和挑出和上的=MATCH相关两点。known_y'sknown_x's

    这将适用于 Excel 2007，但=FORECAST.LINEAR必须更改为=FORECAST（即将折旧）。

    • 2

相关问题