主页 / computer / 问题 / 1663824
Accepted
Lluser
Asked: 2021-07-22 02:05:38 +0800 CST

Excel：从单个输入中获取范围地址（寻找紧凑的公式）

  • 772

我正在尝试从单个输入中获取绝对范围地址。像这样的东西。

Formula
=SOME.MAGIC(A1:B10)

Output (string)
"$A$1:$B$10"

尝试 1

我能够得到这个结果，但是使用以下（数组）公式非常复杂的方法。

{=ADDRESS(MIN(ROW(A1:B10)),MIN(COLUMN(A1:B10)),1,1)&":"&ADDRESS(MAX(ROW(A1:B10)),MAX(COLUMN(A1:B10)),1,1)}

其中（如您所见）字符串A1:B10使用了四次。

尝试 2

我的另一个尝试是使用 function FORMULATEXT。一个范围的链接只存在一次，但是使用一个更多的单元格是令人讨厌的解决方法，并且仅适用于相对地址相对较好。它不适用于命名范围。

C1=$A$1:$B$10
C2=MID(FORMULATEXT(C1),2,LEN(FORMULATEXT(C1))-1) //Returns string "$A$1:$B$10" ✓

But
C1=A1:B10
C2=MID(FORMULATEXT(C1),2,LEN(FORMULATEXT(C1))-1) //Returns string "A1:B10" ✘

And
C1=Named_range
C2=MID(FORMULATEXT(C1),2,LEN(FORMULATEXT(C1))-1) //Returns string "Named_range" ✘

尝试 3

下一步是尝试 1+2 的组合。它有效，但我对此不满意。

C1=A1:B10
C2=MID(FORMULATEXT(C1),2,LEN(FORMULATEXT(C1))-1)
C3{=ADDRESS(MIN(ROW(INDIRECT(C2))),MIN(COLUMN(INDIRECT(C2))),1,1)&":"&ADDRESS(MAX(ROW(INDIRECT(C2))),MAX(COLUMN(INDIRECT(C2))),1,1)}

是否有更简单的方法（不太复杂的公式）具有相同的输出？

microsoft-excel worksheet-function

3 个回答

  1. 考虑用户定义的函数：

    Option Explicit

Public Function adres(rng As Range) As String
    adres = rng.Address(True, True)
End Function

    在此处输入图像描述

    用户定义函数 (UDF) 非常易于安装和使用：

    1. ALT-F11 调出 VBE 窗口
    2. ALT-I ALT-M 打开一个新模块
    3. 粘贴这些东西并关闭 VBE 窗口

    如果您保存工作簿，UDF 将与它一起保存。如果您使用的是 2003 年以后的 Excel 版本，则必须将文件另存为 .xlsm 而不是 .xlsx

    要删除UDF：

    1. 如上所述调出 VBE 窗口
    2. 清除代码
    3. 关闭 VBE 窗口

    要使用Excel 单元格中的 UDF：

    =adres(A1:B10)

    要了解有关宏的更多信息，请参阅：

    http://www.mvps.org/dmcritchie/excel/getstarted.htm

    和

    http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

    有关 UDF 的详细信息，请参阅：

    http://www.cpearson.com/excel/WritingFunctionsInVBA.aspx

    必须启用宏才能使其正常工作！

    • 5
  2. Best Answer

    这将是另一种方式：

    =CELL("address",A1:B10)&":"&CELL("address",INDEX(A1:B10,ROWS(A1:B10),COLUMNS(A1:B10)))

    如果您有 Office 365，请使用 LET 仅引用一次范围

    =LET(ref, A1:B10, CELL("address",ref)&":"&CELL("address",INDEX(ref,ROWS(ref),COLUMNS(ref)))
    • 3

  3. 实际上，您的尝试#1 正是这样做的方法。如果您正在寻找一种使其看起来更像函数的方法（较少重复引用/“参数”地址的单次使用），最好的方法是在 Office 365 中使用 LAMBDA。使用 LAMDA，您可以为一个命名范围，将 MAGIC 定义为

    =LAMBDA(ref, ADDRESS(MIN(ROW(ref)),MIN(COLUMN(ref)),1,1)&":"&ADDRESS(MAX(ROW(ref)),MAX(COLUMN(ref)),1,1)}

    然后在工作表中使用 =MAGIC(A1:B10) 。

    • 2

相关问题