主页 / computer / 问题 / 1633756
Accepted
sunknudsen
Asked: 2021-03-17 04:26:47 +0800 CST

为什么 echo “$USER:staff” 会抛出 zsh: bad replacement？

  • 772

困惑是因为echo "PATH=$PATH:/usr/local/sbin"没有（认为它与:）有关。

此外，在 Bash 中，这两个命令都按我的预期工作。

$ echo "PATH=$PATH"
PATH=/usr/local/bin

$ echo "PATH=$PATH:/usr/local/sbin"
PATH=/usr/local/bin:/usr/local/sbin

$ echo "$USER:staff"
zsh: bad substitution
zsh

1 个回答

  1. Best Answer

    因为:safter$USER被解释为扩展修饰符。如果您执行以下操作，您可以清楚地看到这一点：

    % autoload -Uz compinit; compinit       # Init completion system
% zstyle ':completion:*' group-name ''  # Enable completion grouping
% zstyle ':completion:*' format '%d'    # Add titles to the groups
% print $USER: # and press Tab or ^D right after the `:`
modifier
&  -- repeat substitution
A  -- as ':a', then resolve symlinks
P  -- realpath, resolve '..' physically
Q  -- strip quotes
a  -- absolute path, resolve '..' lexically
c  -- PATH search for command
e  -- leave only extension
g  -- globally apply s or &
h  -- head - strip trailing path element
l  -- lower case all words
q  -- quote to escape further substitutions
r  -- root - strip suffix
s  -- substitute string
t  -- tail - strip directories
u  -- upper case all words

    从上面的列表中可以看出，:/它不是扩展修饰符。

    是否建议始终使用${PATH},${USER}等...然后？

    不，通常只使用 就可以了$USER，但有时，如您所见，需要使用${USER}。:)

    但是，关于您问题中的代码，我可以给您另外两个在 Zsh 中使用的建议：

    % print $PATH
/usr/local/bin

% print $path
/usr/local/bin

% path+=/usr/local/sbin  # $path is an array, not a string

% print $PATH            # $path and $PATH are "tied" & automatically in sync
/usr/local/bin:/usr/local/sbin

% print -c $path         # Print the items in columns, like `ls`
/usr/local/bin   /usr/local/sbin

% print -l $path         # Print one item per line, like `ls -l`
/usr/local/bin
/usr/local/sbin

% path+=/usr/local/sbin

% print -c $path       
/usr/local/bin   /usr/local/sbin  /usr/local/sbin

% typeset -U PATH path   # Make each item unique/Eliminate duplicates

% print -c $path       
/usr/local/bin   /usr/local/sbin
    • 3

相关问题