主页 / computer / 问题 / 1632955
Accepted
Teodros IV
Asked: 2021-03-13 15:51:49 +0800 CST

识别非重复项并复制到 Excel 上的新列

  • 772

我有一组两列。F 列列出了已安排的与会者的姓名。当他们将徽章扫描到 A 列时，C 列使用匹配和索引来提取与会者姓名。我对 C 列和 F 列感兴趣。

在 C 列和 F 列上使用条件格式“唯一”，我可以将步入识别为将在 C 列上提取的名称不会出现在我在 F 列上的预定列表中。

我正在寻找一个公式，而不是使用宏将步入（不重复的值）拉到名为“步入”的单独列中）。

在这种情况下，高级过滤器和“唯一”公式无法工作，因为我正在寻找只出现一次的值。为什么？因为如果“John”同时出现在 C 和 F 列上，那么高级过滤器和唯一公式会将单个“John”记录为唯一值。但我对这件事的兴趣不是出现在两栏上的约翰，而是出现在 C 栏上但不在 F 栏上的保罗。

简而言之 - 我需要识别“非重复值或单个值”而不是唯一值。

首先十分感谢。

你们中的大多数人已经了解我在寻找什么，但为了消除任何误解，我举了一个例子。在现实生活中，我手动将步入记录在同一工作簿的另一个工作表的列中。

我正在查看的示例

microsoft-excel windows-10

2 个回答

  1. Best Answer

    如果您有 Office 365 Excel，则可以使用以下方法生成一个步入列表：

    =LET(x,1/ISNA(MATCH(Attendees,Scheduled,0))*ROW(Attendees),y,AGGREGATE(15,6,x,SEQUENCE(COUNT(x)))-1,INDEX(Attendees,y))

    Attendees并Scheduled参考明显的范围。

    在此处输入图像描述

    如果您有早期版本，则可以使用更复杂的公式，但了解您正在使用的 Excel 版本会很有帮助。

    一种可能性是：

    =INDEX(Attendees,AGGREGATE(15,6,1/ISNA(MATCH(Attendees,Scheduled,0))*ROW(Attendees)-1,ROW(INDEX($A:$A,1):INDEX($A:$A,COUNT(1/ISNA(MATCH(Attendees,Scheduled,0))*ROW(Attendees))))))

    您可能需要也可能不需要通过按住+来“确认”为数组公式。如果您正确执行此操作，Excel 将在公式周围放置大括号，如公式栏中所观察到的那样。ctrlshiftenter{...}

    请注意，在这两个公式中，-1(as inAGGREGATE(...)-1是针对定义范围的标题行进行调整以便能够使用该INDEX函数。该INDEX函数查看数组中的位置；而ROW查看绝对行号位置。如果您的范围开始于 以外Row 1，您将相应地调整该因素。

    • 1

  2. 阅读您的描述，我制作了以下数据：

    在此处输入图像描述

    保罗走了进来，而其他人则安排了他们的出席。（列A不重要。）

    我认为最简单的方法是使用MATCH. 例如，D2你可以使用这样的东西：

    =IFERROR(IF(MATCH(C2,F:F,0),"scheduled"),"WALK IN")

    在此处输入图像描述C

    作为另一种方法，您可以在 column 上放置条件格式C公式：

    =AND(NOT(IFERROR(MATCH(C1,F:F,0),0)),C1<>"", C1<>"attendees")

    在此处输入图像描述

    正如您坚持的那样，这是包含唯一值的单独列的公式（在这种情况下只有 Paul）。

    这是一个数组公式（使用Ctrl+Shift+Enter而不是通常的 Enter 输入数组公式）。

    数组公式在 Excel 表格对象中不起作用，并且它们在提供特定范围而不是完整列时表现最佳（因为它们实际上会对 100 万行的整列中的每个单元格进行计算）。因此，由于特定范围是优选的，因此维护此类公式可能会很痛苦。

    要使此公式起作用，还需要一个附加列。我的意思是，上面第一个备选方案中描述的“步入”列。因此，如果您选择此选项，您总共将有 2 个额外的列。

    如果您仍然想这样做，这是公式：

    =IFERROR(
   INDEX(
      $C$2:$C$5,
      SMALL(
         IF(
            $D$2:$D$5<>"WALK IN",
            "",
            ROW($D$2:$D$5)-MIN(ROW($D$2:$D$5))+1),
         ROW(D2)-1)),
   "")

    在此处输入图像描述

    • 0

相关问题