主页 / computer / 问题 / 1605128
Accepted
Curt
Asked: 2020-11-26 14:34:40 +0800 CST

从 Excel 中的另一个日期和时间中减去一个日期和时间得到错误的结果

  • 772

我正在尝试在单元格格式自定义中减去日期/时间：mm/dd/yyyy hh:mm:ss AM/PM。从另一个时间以相同的格式。我已经尝试了很多网站关于如何做到这一点的想法，但没有一个例子展示了我希望如何做到这一点。已尝试使用 DATEDIF 公式、带有 TIMEVALUE 和 MINUTE(TIME(HOUR 等等的公式，但没有任何效果......所以假设 A1 = 11-25-2020 3:30:00 PM A2 = 09-16-2020 7：上午 30:00 和 A3 = SUM(A1-A2) = 00/03/10 08:00:00 A3 的格式为 yy/mm/dd hh:mm:ss

A1 转换为一般时 = 44160.64583 A2 转换为一般时 = 44090.3125 A3 转换为一般时 = 70.33333333 所以日期/时间到数字的转换看起来正确，数学看起来正确问题在于 A3 中数字到日期/时间的转换.

有谁知道这个问题的任何解决方案？

提前谢谢你

microsoft-excel date-time

3 个回答

  1. 在最终格式中很难看出您的目的，因此猜测不太可能是正确的。尽管如此，我会做出最好的猜测，并认为您的目的是将时间差异显示为当年的一部分，作为一年中的日期，给人一种与一年中的百分比不同的感觉. 所以我猜你在这个例子中想要的结果是“20/03/10 08:00:00”......

    您可以通过将 43830 添加到 A3 中的减法来实现。因此，经过的时间将相对于年初。您可以通过使用 DATEVALUE() 并向其传递一个构造字符串来查找当前年份并将“1/1/”连接到它，从而在未来证明这一点。

    （如果这不是想法，您需要编辑以“澄清”（即：提及您正在寻找的某种东西）。再过几个小时，即使在编辑之后也没有人会回答它也可能被投票关闭。）

    • 0
  2. Best Answer

    当然，问题是年份和月份都没有固定的天数，因此需要单独计算差异。

    要将值输出为字符串，您可以尝试：

    =TEXT(DATEDIF(A2,A1,"y"),"[<>1]0 ""yrs,""; 0 ""yr,""")&
  TEXT(DATEDIF(A2,A1,"ym"),"[<>1] 0 ""months,""; 0 ""month,""") &
  TEXT(DATEDIF(A2,A1,"md")-(MOD(A2,1)>MOD(A1,1)),"[<>1] 0 ""days,"";0 ""day, """) &
  TEXT(HOUR(MOD(A1,1)-MOD(A2,1)+(MOD(A2,1)>MOD(A1,1))),"[<>1] 0 ""hrs,""; 0 ""hr,""") &
  TEXT(MINUTE(MOD(A1,1)-MOD(A2,1)+(MOD(A2,1)>MOD(A1,1))),"[<>1] 0 ""mins,""; 0 ""min""") &
  TEXT(SECOND(MOD(A1,1)-MOD(A2,1)+(MOD(A2,1)>MOD(A1,1))),"[<>1] 0 ""secs""; 0 ""sec""")

    请注意，我们使用布尔值(MOD(A2,1)>MOD(A1,1))来确定是否从日期和时间值中添加/减去一天，以说明结束时间在开始时间之前。

    在此处输入图像描述

    如果您想要不同的输出格式，那是可行的。但我会坚持输出为 * text，因为某些差异无法用日期格式表达；例如01-02-29( 1 yr, 2 months, 29 days)，因为当年 2 月没有 29 天）。

    • 0

  3. 由于您使用的是日期时间戳（日期和时间一起），那么您必须使用不同的方法。您不能使用该DATEVALUE函数，因为它将表示为文本的日期转换为正确的 Excel 日期。

    在此处输入图像描述

    • 如果您想获得年、月和日的差异，请在单元格 O5 中使用此公式：

      =DATEDIF(O3,O1,"Y") & " Years, " & DATEDIF(O3,O1,"YM") & " Months, " & DATEDIF(O3,O1,"MD") & " Days"

    • 要获得总天数公式在 O7 中：

      =-INT(O3-O1) & " Days"

    • 如果要计算总小时数，请在单元格 O9 中计算：

      =O1-O3

    • 单元格 O9 上的应用格式是[h]:mm:ss，其中将[h]数据评估为 24 小时时间。

    ：编辑：

    通过评论 OP 已经透露，确切的需要是找到两个日期时间戳之间关于年、月、日和小时、分钟、秒的差异。

    为此，我想提出两个可能的公式。

    在此处输入图像描述

    • 单元格 O14 中的公式：

      =DATEDIF(O12,NOW(),"Y")&" Years, "&DATEDIF(O12,NOW(),"YM")&" Months, "&DATEDIF(O12,NOW(),"MD")&" Days,  "&TEXT(NOW()-O12,"h"" hrs ""m"" mins ""s"" secs""")

    • 单元格 O16 中的公式：

       =INT(NOW()-O12)&" days "&TEXT(NOW()-O12,"h"" hrs ""m"" mins ""s"" secs""")

    笔记：

    • 我使用NOW()了当前日期和时间的函数，它是可编辑的。

    • 记住函数NOW()是可变的，所以为了避免当前日期和时间的频繁变化，最好NOW()用任何CURRENT DATE & TIME值替换。

    根据需要调整公式中的单元格引用。

    • -1

相关问题