主页 / computer / 问题 / 1512929
Accepted
Rayearth
Asked: 2019-12-28 11:42:42 +0800 CST

VBA检查范围内的所有单元格是否为空，然后再继续

  • 772

我想在执行下一行代码之前进行检查。

我写了一个这样的简单结构，但它检查范围内的第一个单元格，如果该单元格为空，由于满足要求和 GoTo 标签，它会执行下一步。

我需要它做的是检查所有单元格，并且仅在所有单元格为空时才继续（在单独检查每个单元格后不进入下一步）。如果其中之一不为空 - 潜艇应该退出。

是否可以使用这样的代码来做到这一点，或者在这种情况下我需要不同的方法吗？

Sub Check_and_execute
Dim Cell As Range

    For Each Cell In ThisWorkbook.Sheets("Sheet1").Range("A1:A10")
        If Cell.Value = "" Then
            GoTo NextStep
        Else
            MsgBox "Not all cells are empty."
            GoTo EndSub
        End If
    Next

NextStep:
'code

EndSub:
End Sub
microsoft-excel vba

3 个回答

  1. 不需要循环：

    Sub Check_and_execute()
    If Application.WorksheetFunction.CountA(ThisWorkbook.Sheets("Sheet1").Range("A1:A10")) > 0 Then
        MsgBox "Not all cells are empty."
        Exit Sub
    End If

    'code
End Sub
    • 3
  2. Best Answer

    像这样的东西？

    Sub Check_and_execute
Dim Cell As Range
Dim CellsEmpty as boolean
CellsEmpty = True

For Each Cell In ThisWorkbook.Sheets("Sheet1").Range("A1:A10")
    If Cell.Value <> "" Then 
        CellsEmpty = False
        Exit for
    End if
Next

If CellsEmpty = True then
    'code
Else
    MsgBox "Not all cells are empty."
End if

End Sub
    • 2

  3. 我不确定这是否更快，但它更短。您可以使用一行代码检查范围是否为空白（包括将空字符串计为空白）：

    rg.Cells.Count = WorksheetFunction.CountBlank(rg)

    当您需要测试一个范围是否全为空白时，您可以将其编写为要调用的函数：

    Function allBlank(rg As Range) As Boolean
    allBlank = (rg.Cells.Count = WorksheetFunction.CountBlank(rg))
End Function

    你可以在你的宏中使用它：

    Sub Check_and_execute()
    If Not allBlank(ThisWorkbook.Sheets("Sheet1").Range("A1:A10")) Then
        MsgBox "Not all cells are empty"
        Exit Sub
    Else
        'your code
        ' ...
        ' ...
    End If
End Sub
    • 1

相关问题