主页 / coding / 问题 / 79594519
Accepted
HSHO
Asked: 2025-04-27 07:32:56 +0800 CST

如何在 Google 表格中动态地转置日期旁边的分组值？

  • 772

我在 Google 表格中有一个数据集，其中日期出现在A 列中，值（如项目名称）出现在B 列中。

数据如下：

一个 B
2024年4月1日 项目A
项目 B
项目C
2024年4月5日 项目 D
项目 E
2024年4月10日 项目 F
项目 G
项目 H
第一部分

我想将项目名称水平转置到每个日期旁边-
这意味着每个日期的对应值将分布到C、D、E 列等。

预期结果：

一个 B 碳 D 埃
2024年4月1日 项目A 项目 B 项目C
2024年4月5日 项目 D 项目 E
2024年4月10日 项目 F 项目 G 项目 H 第一部分

我尝试使用FILTER、TRANSPOSE和等公式ARRAYFORMULA，
但只能获得第一次约会的结果或不完整的结果。

我怎样才能像预期结果一样动态填充所有行？

最好使用公式，而不是脚本或手动数据透视表。

我试过了，但这个公式不准确

=IF(A2<>"", TRANSPOSE(FILTER(B$2:B, MMULT(N(ROW(A$2:A$1000)<=ROW(A2))*(A$2:A<>""), SEQUENCE(COLUMNS(B$2:B),1,1,0))=1)), "")

提前致谢！

google-sheets

2 个回答

  1. 您可以使用

    =LET(
   dates, A2:A,
   items, B2:B,
   dates.fill, SCAN(, dates, LAMBDA(a, c, IF(c="", a, c))),
   MAP(
     UNIQUE(TOCOL(dates, 1)),
     LAMBDA(date, {date, TOROW(FILTER(items, dates.fill = date), 1)})
   )
 )

    工作原理

    首先，我们用前一个非空日期填充日期列中的每个空白单元格，SCAN并将结果分配给变量dates.fill

    dates.fill ← SCAN(, dates, LAMBDA(a, c, IF(c="", a, c)))

    date然后，我们使用该函数对日期列中的每个日期进行迭代，并使用函数MAP根据条件将日期水平堆叠到过滤项中dates.fill = dateFILTER

    MAP(
  UNIQUE(TOCOL(dates, 1)),
  LAMBDA(date, {date, TOROW(FILTER(items, dates.fill = date), 1)})
)
    • 2
  2. Best Answer

    您可以尝试：

    =LET(a, A:B,
     b, INDEX(a, , 1),
     c, INDEX(a, , 2),
     d, SCAN("", b, LAMBDA(x, y, IF(y="", x, y))),
     e, UNIQUE(d),
     BYROW(e, LAMBDA(x, HSTACK(x, TOROW(FILTER(c, d=x), 1)))))

    输出

    一个 B 碳 D 埃
    2024年4月1日 项目A 项目 B 项目C
    2024年4月5日 项目 D 项目 E
    2024年4月10日 项目 F 项目 G 项目 H 第一部分

    参考

    • 1

相关问题