主页 / coding / 问题 / 79591766
Accepted
Ben
Asked: 2025-04-25 11:35:24 +0800 CST

来自 UNIQUE VSTACK 的 COUNTIFS

  • 772

我有一张表，我想根据第三列的值来计算两列中值的出现次数，并且为了便于阅读，我希望能够看到旁边带有计数的唯一值。

例如：

人员1 Person2 数字
账单 戴夫 2
戴夫 约翰 2
约翰 账单 1

我想根据第三列的值来查看每个人的名字出现了多少次。由于这是一个流动文档，所以唯一需要更新的列是这三列，因此我需要创建一个新的列，其中包含 A 和 B 这两个唯一值，如果 C 的值 = 2

到目前为止我想到的是：

=UNIQUE(VSTACK(A2:A100,B2:B100))

效果很好，但接下来根据 C 的值计算出现次数，我遇到了麻烦。我试过

=COUNTIFS(A2:B100,E2,C2:C100,">1")

但它总是出现“值是错误的数据类型。我已确保列是正确的类型，例如 C 是一个数字，并且将 UNIQUE 函数中的值复制到单独的列中，这样它就不会尝试堆叠函数。

我尝试过其他类似的功能，COUNT(UNIQUE(FILTER())但这并不能消除无效计数，还有另一种解决方案，我不知道它是否有效，因为我无法理解该功能：

=SUM(--(FREQUENCY(IF(C2:C18=2,MATCH(A2:A18,B2:B18,0)),ROW(A2:B18)-ROW(A2)+1)>1))
excel

4 个回答

  1. Best Answer

    使用此输入表：

    人员1 Person2 数字
    账单 戴夫 2
    戴夫 约翰 2
    约翰 账单 1
    账单 约翰 2
    戴夫 账单 2
    约翰 账单 1
    汤姆 账单 2
    账单 约翰 1
    戴夫 账单 2
    约翰 账单 2

    这个公式：

    =LET(toonecol,VSTACK(HSTACK(A2:A18,C2:C18),B2:C18),
filt,FILTER(toonecol,CHOOSECOLS(toonecol,2)=2),
cnt,BYROW(UNIQUE(TOCOL(A2:B18)),LAMBDA(x,SUM(IF(filt=x,1,0)))),
DROP(HSTACK(UNIQUE(TOCOL(A2:B18)),cnt),-1))

    此表中的结果

    - -
    账单 6
    戴夫 4
    约翰 3
    汤姆 1

    toonecol包含与列连接的两列名称Number。filt仅包含
    cnt计数Number=2
    的唯一名称出现次数
    ，最后一行将唯一名称与结果连接起来。

    • 3

  2. 为了好玩并且如果适用的话，尝试利用GROUPBY()：

    在此处输入图片描述

    =LET(
     a, TOCOL(FILTER(A2:B11,C2:C11=2,"")),
     GROUPBY(a,a,ROWS,,0))

    使用Black cat提供的数据

    • 3

  3. 一如既往，有多种解决方案。使用名为tblData

    
=LET(
    uniqueNames,UNIQUE(TOCOL(tblData[[Person1]:[Person2]])),
    cnt,BYROW(uniqueNames,
        LAMBDA(n,
            ROWS(
                FILTER(tblData,(tblData[Number]=2)*((tblData[Person1]=n)+(tblData[Person2]=n)))
                ))),
    HSTACK(uniqueNames,cnt)
    )

    列表 tblData 的每个唯一名称都按数字和人员姓名进行过滤。cnt = 过滤行数。

    x

    • 2

  4. 另一个：

    =LET(a,TOCOL(FILTER(A1:B10,C1:C10=2)),b,UNIQUE(a),c,BYROW(b,LAMBDA(x,SUM(1*(x=a)))),HSTACK(b,c))

    结果：

    在此处输入图片描述

    • 1

相关问题