主页 / coding / 问题 / 79565732
Accepted
Ezio
Asked: 2025-04-10 12:42:20 +0800 CST

COUNTIF 仅使用 DATE 和名称匹配条件

  • 772

我的任务是统计销售代理每天能拿到多少线索。所以我创建了一个电子表格，数据会从 CRM 平台自动填充，并且还专门为追踪器创建了一个标签页。

我使用两个条件进行计数：日期和代理人姓名。代理人姓名没有问题。唯一的问题是日期。

问题是，Countif 不计算单元格，因为它无法匹配我的单元格引用（仅日期），而在潜在客户数据中，它包含日期和时间。

此外，潜在客户数据必须放在单独的选项卡上，我无法合并这两个选项卡，它应该被隐藏和锁定，因为其中的数据是由 CRM 平台自动填充的。

我创建了一个类似的电子表格作为示例。链接如下： https ://docs.google.com/spreadsheets/d/1-kEKHCQk1qF_k8oPnu-166fYdHukozfChEQ4bixwwB0/edit?usp=sharing

任何有关此事的指导或帮助都将不胜感激。

date

3 个回答

  1. 使用query()，像这样：

    =query(
  'Leads Data'!A1:B,
  "select Col2, count(Col2) 
   where Col2 is not null
   group by Col2
   pivot toDate(Col1)",
  1
)

    参见query()。

    • 1

  2. 你可以尝试这个公式

    =BYCOL(B$1:E$1, LAMBDA(date, ARRAYFORMULA(IF(A2:A13="", "", COUNTIFS('Leads Data'!$B:$B, A2:A13, 'Leads Data'!$A:$A, ">="&date, 'Leads Data'!$A:$A, "<"&date+1)))))

    我刚刚在给定的电子表格中添加了一些日期，以便测试它是否正常工作，我使用COUNTIF检查每行的名称和日期范围，并使用IF 函数避免空行得到零，并使用ARRAYFORMULAA2:A13一次性获取所有名称（ ），最后使用BYCOL函数逐列获取，以便您可以使用单个公式自动填充整个表格。

    2025年4月4日 2025年5月4日 2025年6月4日 2025年7月4日
    朱莉娅 8 1 2 2
    亚历克斯 2 1 1 1
    安德鲁 5 2 1 1
    灰 4 1 1 1
    艾琳 3 1 1 1
    约翰 4 1 1 3
    乔希 3 2 2 2
    朱莉娅 8 1 2 2
    射线 5 1 2 1
    山姆 5 1 1 2
    史蒂夫 2 1 1 2
    特伦特 5 3 3 1
    • 0
  3. Best Answer

    您还可以使用以下内容获得更加结构化的数据摘要：

    您可以选择月份和/或输入年份来相应地过滤数据：

    在此处输入图片描述

    =LET(
  data, 'Leads Data'!A2:B,
  m, MONTH(DATEVALUE(B1 & " 1")),
  y, VALUE(Q1),
  nm, INDEX(data,,2),
  dt, INDEX(data,,1),
  uniq, UNIQUE(nm),
  names, SORT(FILTER(uniq, uniq <> "")),
  cnt, MAKEARRAY(ROWS(names), 31,
        LAMBDA(r, c,
          COUNTIFS(nm, INDEX(names, r, 1),
                   dt, ">=" & DATE(y, m, c),
                   dt, "<" & DATE(y, m, c) + 1)
        )
      ),
  rs, BYROW(cnt, LAMBDA(row, SUM(row))),
  ct, BYCOL(cnt, LAMBDA(col, SUM(col)))
, VSTACK(
      HSTACK(names, cnt, rs),
      HSTACK(ROWS(names), ct, SUM(rs))
   )
)

    已应用必要的条件格式来改进摘要

    更新：

    楼主：想要一份每周报告，并指定开始日期（星期一）

    在此处输入图片描述

    =LET(
  raw, UNIQUE(Sample!E2:E),
  names, SORT(FILTER(raw, raw<>"")),
  counts, MAKEARRAY(ROWS(names),7,LAMBDA(r,c,COUNTIFS(Sample!E2:E,INDEX(names,r),Sample!B2:B,">="&($D$1+c-1),Sample!B2:B,"<"&($D$1+c)))),
  rowTotals, BYROW(counts,LAMBDA(r,SUM(r))),
  dataBlock, HSTACK(names,counts,rowTotals),
  totals, HSTACK(ROWS(names),BYCOL(counts,LAMBDA(c,SUM(c))),SUM(rowTotals)),
  VSTACK(dataBlock,totals)
)
    • 0

相关问题