主页 / coding / 问题 / 79561114
Accepted
Lean Liu
Asked: 2025-04-08 11:21:44 +0800 CST

使用 groovy 动态添加 XML 节点

  • 772

我有一个类似下面的 XML

<root>
<item>
<refitemid>10</refitemid>
</item>
</root>

我的要求是首先向添加一个节点 <additional_info> ，然后根据获取的数据向 <additional_info> 添加新节点，以便新的 XML 呈现如下

<root>
<item>
<refitemid>10</refitemid>
<additional_info>
<sn><id>1</id></sn>
<sn><id>2</id></sn>
</additional_info>
</item>
</root>

我尝试使用下面的 Groovy 脚本来实现这一点。

def oPayload = new XmlSlurper().parseText(message.getBody() as String); //get above original XML data
if (oPayload.root.item.additional_info == "" || oPayload.root.item.additional_info == null) {
    oPayload.root.item.appendNode {
        additional_info {}
    }
}
for (int i = 1; i < 3; i++) {
    oPayload.root.item.additional_info.appendNode {
        sn {
            id(i.text())
        }
    }
}

oPayload = XmlUtil.serialize(oPayload)

不幸的是，上面的代码根本不起作用，因为结果（在 oPayload 中）将变成如下所示：

<root>
<item>
<refitemid>10</refitemid>
</additional_info>
</item>
</root>

您能分享一下如何实现该要求吗？非常感谢。

xml

2 个回答

  1. Best Answer

    如果您使用XMLParser，我认为事情会变得更容易一些：

    
import groovy.xml.XmlParser
import groovy.xml.XmlNodePrinter

def xmlText = '''<root>
<item>
<refitemid>10</refitemid>
</item>
</root>'''

def root = new XmlParser().parseText(xmlText)
def item = root.item[0]

def additionalInfo = item.additional_info?.first() ?: item.appendNode('additional_info')

(1..2).each { i ->
    additionalInfo.appendNode('sn').appendNode('id', i.toString())
}

def writer = new StringWriter()
new XmlNodePrinter(new PrintWriter(writer)).with {
    preserveWhitespace = true
    print(root)
}

println writer.toString()
    • 0

  2. 如果真的使用XmlSlurper，那么修改xml树就没那么好了：

    import groovy.xml.XmlSlurper
import groovy.xml.XmlNodePrinter
import java.io.StringWriter
import java.io.PrintWriter

// Your source xml
def xmlText = '''<root>
    <item>
        <refitemid>10</refitemid>
    </item>
</root>'''

def root = new XmlSlurper().parseText(xmlText)
def item = root.item[0]

// Add `additional_info` node and childs
if (!item.children().any { it.name() == 'additional_info' }) {
    item.appendNode {
        additional_info()
    }
}

(1..2).each { i ->
    item.additional_info.appendNode {
        sn {
            id(i) // Directly use the integer, toString() is implicit
        }
    }
}

def writer = new StringWriter()
new XmlNodePrinter(new PrintWriter(writer)).with {
    preserveWhitespace = true
    print(root)
}

println writer.toString()
    • 0

相关问题