主页 / coding / 问题 / 79556561
Accepted
ezekiels
Asked: 2025-04-05 12:36:04 +0800 CST

将 Sum 与 Vlookup 结合起来

  • 772

我有这些数据（表 1）：

Column A
1999
5000
6666

还有表 2：

Col.C | Col.D (range)|  Col.E (margin)
1000  | 1000 - 1260  |  830
1261  | 1261 - 1261  |  0
1262  | 1262 - 1513  |  830
1514  | 1514 - 1514  |  0
1515  | 1515 - 2522  |  830
2523  | 2523 - 2523  |  0
2524  | 2524 - 5044  |  960
5045  | 5045 - 5045  |  0
5046  | 5046 - 5549  |  960
5550  | 5550 - 5550  |  0
5551  | 5551 - 6558  |  960
6559  | 6559 - 6559  |  0
6560  | 6560 - 6999  |  960

A 列中的金额有一个相应的范围（D 列），即：1999 在 1515 - 2522 范围内。因此利润是 830。我的问题是，如何对表 1 中的所有利润进行求和？

我已经尝试过这些公式：

formula1 =SUM(VLOOKUP(VLOOKUP(A:A;C:D;2);D:E;2;0)) 
formula2 =SUMIF(D:D;VLOOKUP(A:A;C:D;2);E:E)

但结果只显示第一行的边距，而不是总边距

Result formula1 : 830
Result formula2 : 830

使用辅助列会更容易，结果将如下所示：

Col.A  | Margin
1999   | 830
5000   | 960
6666   | 960

问题是，我不想使用任何辅助列，因为我的数据每个月有 100,000 行，辅助列会因为公式而减慢我的 Excel 速度。

我只需要知道总利润（本例中是 2750）。有没有办法不用辅助列就能得到这个结果？我能想到的办法就是结合使用 SUM/SUMIF 和 Vlookup。我找了好几天，在这个论坛里找到了很多类似的案例，但都没找到。

提前致谢，如能提供任何帮助我们将不胜感激。

excel-formula

1 个回答

  1. Best Answer

    以下所有三个公式都对我有用，请使用以下任何一种：

    =SUM(LOOKUP(Table1[Column A],Table2))

    =SUM(XLOOKUP(Table1[Column A],
 --TEXTBEFORE(Table2[Col.D (range)]," "),
 Table2[Col.E (margin)],,-1))

    =SUM(SUMIF(Table2[Col.D (range)],
 LOOKUP(Table1[Column A],Table2[[Col.C]:[Col.D (range)]]),
 Table2[Col.E (margin)]))

    甚至所使用的公式在借助TRIMRANGE()函数或其引用运算符使用时也有效：

    =SUM(DROP(VLOOKUP(VLOOKUP(A.:.A,C.:.D,2,1),D.:.E,2,0),1))

    或者，

    =SUM(SUMIF(D.:.D,VLOOKUP(A.:.A,C.:.D,2,1),E.:.E))
    • 0

相关问题