主页 / coding / 问题 / 79550050
Accepted
Ananya Batra
Asked: 2025-04-02 16:10:18 +0800 CST

如何对“年初至今”及其在 GF（RGL）中的变化进行建模？

  • 772

我对 GF 的资源语法库还不熟悉，但我想对“年初至今”及其变体（“年初至今”、“今年到目前为止”、“每年”等）等时间表达进行建模。

“今年迄今为止”的词性是什么？我该如何在 GF 的 RGL 中表示“今年迄今为止”？“今年迄今为止”应该是 AP、Adv 还是其他类别？

这是我的第一次尝试：

oper YearToDate : AP = mkAP (mkA "year-to-date") ;

但问题是，这会将短语“年初至今”硬编码为字符串。这意味着其组成部分不可修改（“年初至今”），我不确定如何解释所有变体。

gf

1 个回答

  1. Best Answer

    “今年迄今为止”的词性是什么？我该如何在 GF 的 RGL 中表示“今年迄今为止”？“今年迄今为止”应该是 AP、Adv 还是其他类别？

    最终，最方便的 RGL 类别取决于您想要如何使用它。如果您查看修饰 CN（“普通名词”）的 RGL 概要，您会发现 AP 和 Adv 都可以修饰 CN，但在英语中，它们将使用不同的词序。Adv 是后置修饰语（house [on the hill]:Adv），而 AP 是前置修饰语（[big]:AP house）。根据这些信息，AP 是更好的选择。

    但问题是，这会将短语“年初至今”硬编码为字符串。这意味着其组成部分不可修改（“年初至今”），我不确定如何解释所有变体。

    在我看来，这些看起来像是不同的词汇条目，因此它们作为不同的函数是有道理的。GF 中的“变体”一词表示自由变体，即“year-to-date”、“year up to now”和“yearly”这几个词真正 100% 可以互换，虽然这三个词都会被解析，但只有其中一个会被线性化。通常你不想以这种方式处理变体；相反，你会将单词作为 GF 语法中的不同词汇条目，但外部应用程序会控制在哪种情况下将哪些单词视为可互换。

    也就是说，如果您希望拥有在运行时根据基本单词创建新变体的函数，这绝对是可能的 — 尽管您的特定示例在运行时构建起来有点丑陋，但您需要访问内部内容而不是使用 RGL API。但这肯定是可能的。

    我只是在这里粘贴一个示例语法，如果这不是你想要的，请随时要求澄清或指出。

    抽象语法

    abstract TemporalModifiers = {
  flags startcat = Item ;

  cat
    Item ;
    Kind ;
    Quality ;
    TemporalKind ;

  fun
    -- Quantify a Kind into an Item:
    IndefSg, IndefPl : Kind -> Item ;

    -- Modify a Kind with a Quality
    Mod : Quality -> Kind -> Kind ;

    -- Make a temporal expression into a Quality
    ToDate, UpToNow, Ly : TemporalKind -> Quality ;

    Year, Month : TemporalKind ;

    Sale : Kind ;
}

    具体语法

    concrete TemporalModifiersEng of TemporalModifiers = 
   open Prelude, SyntaxEng, ParadigmsEng in {

  lincat
    Item = NP ;
    Kind = CN ;
    Quality = AP ;
    TemporalKind = {s : CN ; ly : AP} ;

  lin
    IndefSg kind = mkNP aSg_Det kind ;
    IndefPl kind = mkNP aPl_Det kind ;

    Mod quality kind = mkCN quality kind ;

    Ly tk = tk.ly ; -- TemporalKind already contains a field for its -ly adjective, here we just choose it.

    -- With the other two, we need to touch the internals—potentially risky!
    -- This is the lincat of AP in the RGL: {s : Agr => Str ; isPre : Bool} ;
    UpToNow tk = lin AP {
      s = \\_ => (mkUtt (mkNP aSg_Det tk.s)).s ++ "up to now" ;
      isPre = False
      } ;
    ToDate tk = lin AP {
      s = \\_ => (mkUtt tk.s).s ++ BIND ++ "-to-date" ;
      isPre = True
      } ;

    Year = {
      s = mkCN (mkN "year") ;
      ly = mkAP (mkA "yearly")
      } ;

    Month = {
      s = mkCN (mkN "month") ;
      ly = mkAP (mkA "monthly")
    } ;

    Sale = mkCN (mkN "sale") ;

}

    语法输出

    在 GF shell 中测试如下：

    $ gf TemporalModifiersEng.gf
…
TemporalModifiers> gt -depth=3 | l -bind -tabtreebank
IndefPl (Mod (Ly Month) Sale)           monthly sales
IndefPl (Mod (Ly Year) Sale)            yearly sales
IndefPl (Mod (ToDate Month) Sale)       month-to-date sales
IndefPl (Mod (ToDate Year) Sale)        year-to-date sales
IndefPl (Mod (UpToNow Month) Sale)      sales a month up to now
IndefPl (Mod (UpToNow Year) Sale)       sales a year up to now
IndefPl Sale                            sales
IndefSg (Mod (Ly Month) Sale)           a monthly sale
IndefSg (Mod (Ly Year) Sale)            a yearly sale
IndefSg (Mod (ToDate Month) Sale)       a month-to-date sale
IndefSg (Mod (ToDate Year) Sale)        a year-to-date sale
IndefSg (Mod (UpToNow Month) Sale)      a sale a month up to now
IndefSg (Mod (UpToNow Year) Sale)       a sale a year up to now
IndefSg Sale                            a sale
    • 0

相关问题