主页 / coding / 问题 / 79549469
Accepted
Lion King
Asked: 2025-04-02 09:23:34 +0800 CST

如何从汇编中正确调用 printf 函数？

  • 772

我试图用printf汇编语言调用 x86 C 函数，但出现链接错误：error LNK2019: unresolved external symbol _printf referenced in function _main。

.model flat, C
.code
extern printf: proc

main proc
    push offset msg
    push offset fmt
    call printf
    ret
main endp

.data
    msg db "Hello world!", 0
    fmt db "%s", 0
end

我怎样才能解决这个问题？

windows

3 个回答

  1. Best Answer

    这里有几种方法。如果想使用现有的库 -_printf已经在里面了，legacy_stdio_definitions.lib但如果使用它，还需要链接到legacy_stdio_wide_specifiers.lib并ucrt.lib调用__initterm（或将入口点设置为_wmainCRTStartup）在这种情况下，完整的代码看起来像

    .686

.model flat

extern _printf: PROC
extern __imp__exit: DWORD
extern __imp___initterm: DWORD

.code

ep proc

    push offset __xc_z
    push offset __xc_a
    call __imp___initterm
    add esp,8
    
    push offset msg
    push offset fmt
    call _printf
    add esp,8
    
    push eax
    call __imp__exit
    
    ret
ep endp

CRT$XIA SEGMENT ALIAS(".CRT$XIA")
__xc_a DD 0
CRT$XIA ENDS

CRT$XIZ SEGMENT ALIAS(".CRT$XIZ")
__xc_z DD 0
CRT$XIZ ENDS

.const
    msg db "Hello world!", 0
    fmt db "%s", 0
end

    （请注意，这里最好使用.constsection 来.data代替常量数据）

    并将文件链接至

    
link.exe /MAP /MERGE:.CRT=.rdata /SUBSYSTEM:CONSOLE /ENTRY:ep /LARGEADDRESSAWARE /DYNAMICBASE /MACHINE:X86 /SAFESEH:NO /OPT:REF /OPT:ICF /NODEFAULTLIB /EMITPOGOPHASEINFO /EMITVOLATILEMETADATA:NO /LIBPATH:"C:\lib\um\x86" /LIBPATH:"C:\msvc\lib\x86" /LIBPATH:"C:\lib\ucrt\x86" test.obj legacy_stdio_definitions.lib legacy_stdio_wide_specifiers.lib ucrt.lib

    另一种方法 - 构建我自己的 msvcrt.lib（标准 msvcrt.lib 没有，printf尽管它已被导出msvcrt.dll然后使用它）最小方法

    
.686
.model flat
API MACRO name
name proc
name endp
ENDM
.code
API _printf
end

    和msvcrt.def ：

    EXPORTS
printf

    建立

    link.exe /DLL /NOENTRY:ep /LARGEADDRESSAWARE /DYNAMICBASE /MACHINE:X86 /SAFESEH:NO /OPT:REF /OPT:ICF /NODEFAULTLIB /EMITPOGOPHASEINFO /EMITVOLATILEMETADATA:NO /DEF:msvcrt.def msvcrt.obj

    然后就可以使用这个

    .686

.model flat

extern __imp__printf: DWORD
extern __imp__ExitProcess@4: DWORD

.code

ep proc

    push offset msg
    push offset fmt
    call __imp__printf
    add esp,8
    
    push eax
    call __imp__ExitProcess@4
    
    ret
ep endp

.const
    msg db "Hello world!", 0
    fmt db "%s", 0
end

    链接至：

    link.exe /MAP /SUBSYSTEM:CONSOLE /ENTRY:ep /LARGEADDRESSAWARE /DYNAMICBASE /MACHINE:X86 /SAFESEH:NO /OPT:REF /OPT:ICF /NODEFAULTLIB /EMITPOGOPHASEINFO /EMITVOLATILEMETADATA:NO /LIBPATH:"C:\lib\um\x86" /LIBPATH:"C:\msvc\lib\x86" /LIBPATH:"C:\lib\ucrt\x86" test2.obj msvcrt.lib kernel32.lib

    （更通用的为 dll 自动构建库的方法 -此处）

    • 1

  2. 32位代码示例：

            .686p                   ;enable instructions
        .xmm                    ;enable instructions
        .model flat,c           ;use C naming convention (stdcall is default)

;       include C libraries
        includelib      msvcrtd
        includelib      oldnames
        includelib      legacy_stdio_definitions.lib    ;for scanf, printf, ...

        .data                   ;initialized data
pfstr   db      "Hello world!",0dh,0ah,0
        .data?                  ;uinitialized data
        .stack  4096            ;stack (optional, linker will default)

        .code                   ;code 
        extrn   printf:near
        public  main

main    proc

        push    offset pfstr
        call    printf
        add     esp,4 

        xor     eax,eax
        ret
main    endp

        end

    64 位代码示例：

    ;       include C libraries
        includelib      msvcrtd
        includelib      oldnames
        includelib      legacy_stdio_definitions.lib    ;for scanf, printf, ...

        .data
msg     db      "test",00dh,00ah,000h
        .code
        extern  printf:near

main    proc
        sub     rsp,32                  ;caller allocates space for rcx,rcx,r8,r9
        lea     rcx,msg
        call    printf
        xor     eax,eax
        add     rsp,32
        ret
main    endp
        end
    • 0

  3. 如果你使用的是 Windows，那么main该函数实际上应该被命名为_main

    • -1

相关问题