主页 / coding / 问题 / 79472620
Accepted
threedom
Asked: 2025-02-27 20:05:45 +0800 CST

使用解析创建功能查询

  • 772

我在将解析输出转换为功能选择时遇到了问题。我认为你需要将每个输出转换,为enlist

完整问题：

q)dict:exec i by uid from select uid from tb where sym=syms

一：

q)hd:exec date by uid from select date,ht by uid from tb where uid in raze key dict
q)parse"exec date by uid from select date,ht by uid from tb where uid in raze key dict"
?
(?;`tb;,,(in;`uid;(,/;(!:;`dict)));(,`uid)!,`uid;`date`ht!`date`ht)
()
,`uid
,`date

二：

q)ht:key asc(value exec ht by uid from tb where uid in uids)!(value dict)
q)parse"exec ht by uid from tb where uid in uids"
?
`tb
,,(in;`uid;`uids)
,`uid
,`ht
q)

我的尝试：

一（不起作用）：

q)?[(?;`tb;enlist enlist (in;`uid;(,/;(!:;`dict)));(enlist `uid)!enlist `uid;`date`ht!`date`ht);();enlist `uid;enlist `date]
'type
  [0]  ?[(?;`tb;enlist enlist (in;`uid;(,/;(!:;`dict)));(enlist `uid)!enlist `uid;`date`ht!`date`ht);();(enlist`date)!enlist`date]

二（工作）：

q) ?[`tb;enlist(in;`uid;`uids);`uid;(enlist`ht)!enlist`ht]
kdb+

1 个回答

  1. Best Answer

    如果你能提供一些样本数据，那么回答问题总是有帮助的

    q)dict:(1 2;3 4)!2#()
dict
1 2|
3 4|
q)tb:([] date:.z.d+til 4;ht:til 4;uid:1 2 3 6)
q)tb
date       ht uid
-----------------
2025.02.27 0  1
2025.02.28 1  2
2025.03.01 2  3
2025.03.02 3  6
q)?[?[tb;enlist (in;`uid;raze key dict);(enlist `uid)!enlist `uid;`date`ht!`date`ht];();`uid;`date]
1| 2025.02.27
2| 2025.02.28
3| 2025.03.01

    笔记：

    1. 内部查询被包装起来?[...]以便首先执行。
    2. 与其使用解析树版本的代码，不如raze key dict直接执行它更简洁。

    相比于嵌套查询，将它们分解开会更具可读性：

    q)t1:?[tb;enlist (in;`uid;raze key dict);(enlist `uid)!enlist `uid;`date`ht!`date`ht]
q)t1
t1
uid| date       ht
---| -------------
1  | 2025.02.27 0
2  | 2025.02.28 1
3  | 2025.03.01 2
q)?[t1;();`uid;`date]
1| 2025.02.27
2| 2025.02.28
3| 2025.03.01
    • 0

相关问题