主页 / coding / 问题 / 79471366
Accepted
DavidS
Asked: 2025-02-27 08:40:52 +0800 CST

使用 Perl Regex，如何捕获带连字符的单词中连字符的位置？

  • 772

我正在尝试捕获带连字符的单词中所有连字符的位置，以便我可以加载包含这些连字符位置的哈希值（在文本中，而不是单词中）。目前，我正在尝试在非捕获组内使用捕获组……但它只捕获最后一个连字符。

my $word           = shift (@_);
my $word_start_pos = shift (@_);
my $text           = shift (@_);

my $dash_pos  = 0;
my $exp       = 0;
my $pos       = 0;
my $test_char = '';
   
if ($word =~ /^(?:[\p{L&}0-9\.\'\/]{1,}([\-])){7,}[\p{L&}0-9\.\'\/]{1,}$/) {
   foreach $exp (1..$#-) {
      $pos = $-[$exp];
      $dash_pos = $word_start_pos + $pos;
      $test_char = substr($text, $dash_pos, 1);
      if ($test_char =~ /^[\-]$/) {
         &load_changes('-', $dash_pos, 'Dash', ' ', 'Replace');
      }
   }
}
regex

3 个回答

  1. Best Answer
    push @pos, $-[0] while /-/g;

    演示：

    $ perl -Mv5.14 -ne'my @pos; push @pos, $-[0] while /-/g; say "@pos";'
abc-de-fgh
3 6
-----
0 1 2 3 4

    在上下文中，你可以替换

    foreach $exp (1..$#-) {
   $pos = $-[$exp];
   ...
}

    和

    while ( $word =~ /-/g ) {
   my $pos = $-[0];
   ...
}
    • 3

  2. 我认为使用正则表达式完成这项任务没有任何好处。它根本不适合这项工作。以下是两种更简单、更高效的替代方法：

    #!/usr/bin/env perl    

use strict;
use warnings;
use 5.010;

my $str = 'Reg-ex-es are total over-kill for this search-task.';

say '--- using index ---';

my $last = -1;
while (my $pos = index($str, '-', $last)) {
  last if $pos == -1;
  say $pos;
  $last = $pos + 1;
} 

say '--- using split ---';
my @chars = split '', $str;
for my $pos (0 .. $#chars) {
  say $pos if $chars[$pos] eq '-';
}

    输出：

    --- using index ---
3
6
24
45
--- using split ---
3
6
24
45

    （请注意，位置以 0 为基数。）

    • 1

  3. 手动重置pos变量可能不是最好的主意。基本上，这样做会使全局匹配在字符串中来回跳转，而不是从头到尾进行处理。

    @-这是和数组的直接使用@+，它们与值一起工作pos。

    perldoc -v @-
@-      This array holds the offsets of the beginnings of the last
        successful match and any capture buffers it contains. 
        <cut>

perldoc -v @+
@+      This array holds the offsets of the ends of the last successful
        match and any matching capture buffers that the pattern
        contains.
        <cut>

perldoc -f pos
pos     Returns the offset of where the last "m//g" search left off for
        the variable in question ($_ is used when the variable is not
        specified).
        <cut>

    @+相当于pos每个匹配项的值。听起来你想要的是@-值。

    这是代码...

    #!/usr/bin/perl

my $s = q"here-is-a-string-with-a-lot-of-hyphens";
my @hyphenStack;

while($s=~/-/g){
  push(@hyphenStack, $-[0]);
}
for(@hyphenStack){
  print "$_\n";
}

    输出看起来像这样...

    $ perl find.hyphens.pl
4
7
9
16
21
23
27
30

    打了 54 个字

    $ perl -e 'for(@ARGV){print"\n$_\n";while(/-/g){print "$-[0]\n"}}' test-1 test-2 test-3-4-5-6 here-is-a-string-with-a-lot-of-hyphens "here is a string with-spaces-and-hyphens"

test-1
4

test-2
4

test-3-4-5-6
4
6
8
10

here-is-a-string-with-a-lot-of-hyphens
4
7
9
16
21
23
27
30

here is a string with-spaces-and-hyphens
21
28
32
    • -1

相关问题