主页 / coding / 问题 / 79469564
Accepted
lige
Asked: 2025-02-26 19:34:48 +0800 CST

使用重载运算符对派生类型对象数组进行元素级操作

  • 772

我在 Fortran 中定义派生类型并重载一些运算符（例如 + 运算符）。这在处理标量对象时效果很好，我（乐观地）希望这可以无缝地处理这些对象的数组，但事实并非如此。

在下面的例子中，我为 2D 平面中的点定义了一个派生类型，并且重载了 + 运算符来定义两个点的和应该是多少（此操作不需要在数学上有意义——这只是一个简单的例子……）。这适用于单个点，但不适用于点数组。

编译时的错误信息为：

  • gcc：二进制内在数字运算符‘+’中出现意外的派生类型实体

  • ifort：此二元运算对于此数据类型无效。

让它与点数组一起工作的最好/最简单的方法是什么？

module points

  implicit none

  type :: t_point
    integer :: x, y
  contains
    procedure :: add
    generic :: operator(+) => add
  end type t_point

contains

  pure type(t_point) function add(self, other)
    class(t_point), intent(in) :: self, other
    add = t_point(self%x + other%x, self%y + other%y)
  end function add

end module points

program test

  use points

  implicit none

  type(t_point) :: p1, p2, p3

  p1 = t_point(0, 1)
  p2 = t_point(1, 4)
  p3 = t_point(5, -1)

  print*, p1 + p1 ! this works: (0, 2)                                                                                                                             
  print*, p1 + p2 ! this works: (1, 5)                                                                                                                             
  print*, p1 + p3 ! this works: (5, 0)                                                                                                                             
  print*, p2 + p3 ! this works: (6, 3)                                                                                                                             

  print*, (/1, 2, 3/) + (/10, 20, 30/) ! this works with intrinsic data types: (11, 22, 33)                                                                        

  print*, (/p1, p2, p3/) + (/p3, p3, p3/) ! compilers do not like this line                                                                                        

end program test
fortran

2 个回答

  1. Best Answer

    纯函数定义为

      pure type(t_point) function add(self, other)
    class(t_point), intent(in) :: self, other
    add = t_point(self%x + other%x, self%y + other%y)
  end function add

    当用作运算符时，对标量的左侧和右侧进行运算。

    左侧和右侧(/p1, p2, p3/) + (/p3, p3, p3/)是数组，而不是标量：该函数add将不会被使用。

    您需要定义一个接受数组参数的函数。一种自然的方法+是创建add一个元素函数：

      elemental type(t_point) function add(self, other)
    class(t_point), intent(in) :: self, other
    add = t_point(self%x + other%x, self%y + other%y)
  end function add

    （它是纯的，因为它没有被标记为不纯）。这样的add接受两个标量参数和两个相同形状的数组参数。

    当然，请注意，add对于运算符，将 更改为 正是允许和 的+原因。add([p1,p2,p3],[p3,p3,p3])add(p1,p3)

    • 1

  2. 要在 Fortran 中为 t_point 类型启用数组操作，您需要为重载运算符定义一个元素函数。add通过添加elemental关键字来修改您的函数：

      elemental pure type(t_point) function add(self, other)
    class(t_point), intent(in) :: self, other
    add = t_point(self%x + other%x, self%y + other%y)
  end function add

    这允许函数将元素操作应用于 t_point 对象的数组，从而解决编译错误。

    • 1

相关问题