主页 / coding / 问题 / 79465840
Accepted
U. Windl
Asked: 2025-02-25 16:19:52 +0800 CST

需要有关“标量上的实验性键现在被禁止”的帮助，针对 `@a = keys { map { $_ => undef } @a }`

  • 772

我写了一些代码，尝试通过将列表转换为哈希，然后使用该哈希的键作为元素来使列表成员唯一。这在 Perl 5.18 中毫无问题地运行，但现在在 Perl 5.26 中失败了：

@a = keys { map { $_ => undef } @a }

错误信息如下

Experimental keys on scalar is now forbidden at ...
Type of arg 1 to keys must be hash or array (not anonymous hash ({})) at ...

我想避免为此目的创建临时哈希变量。

在 perlfaq4如何从列表或数组中删除重复元素？中有一个解决方案，但它使用了一个单独的临时变量：

my %hash   = map { $_, 1 } @array;
# or a hash slice: @hash{ @array } = ();
# or a foreach: $hash{$_} = 1 foreach ( @array );

my @unique = keys %hash;

#...
my %seen = ();
my @unique = grep { ! $seen{ $_ }++ } @array;
perl

5 个回答

  1. Best Answer

    在足够新的 Perls 上，你可以使用后缀解引用：

    @a = keys { map { $_ => undef } @a }->%*

    较旧的 Perls 将需要中缀解引用：

    @a = keys %{{ map { $_ => undef } @a }}

    或者，您可以使用匿名子程序将生成与重复数据删除分开：

    @a = sub { keys %{{@_}} }->( map { $_ => undef } @a )

    但所有这些都是不必要的，因为List::Util::uniq自从近 23 年前发布的 5.8 版以来，它就一直存在于核心 Perl 中。

    • 4

  2. 有一小段时间，Perl 会尝试猜测当数组或哈希运算符具有引用参数时该做什么。这是在 v5.14 中引入的：

    my @keys = keys $ref;

    事实证明这是一个非常糟糕的想法，因此在 v5.24 中将其删除，在此之后您会收到该错误。perlexperiment列出了实验性功能、它们的引入时间和删除时间。

    通过诊断，您可以获得有关问题的更详细的解释：

    #!/usr/bin/perl
use v5.26;

use diagnostics;

my @a = ( 1, 2, 3, 4, 5, 3, 2 );
@a = keys { map { $_ => undef } @a };

    输出如下：

    Experimental keys on scalar is now forbidden at ... line 7.
Type of arg 1 to keys must be hash or array (not anonymous hash ({})) at ... line 7, near "};"
Execution of ... aborted due to compilation errors (#1)
    (F) An experimental feature added in Perl 5.14 allowed each, keys,
    push, pop, shift, splice, unshift, and values to be called with a
    scalar argument.  This experiment is considered unsuccessful, and
    has been removed.  The postderef feature may meet your needs better.
    
Uncaught exception from user code:
    Experimental keys on scalar is now forbidden at ... line 7.
    Type of arg 1 to keys must be hash or array (not anonymous hash ({})) at ... line 7, near "};"
    Execution of ... aborted due to compilation errors.

    但实际上，谁会关心创建临时变量呢？即使在您尝试使用的匿名引用情况下，您仍然在创建数据结构。在您在问题评论中发布的丑陋解决方案中，您创建了一个匿名子例程，因此您不必使用临时变量。这太疯狂了；您正在做更多工作，而且工作更加复杂，因为您对简单的方法有一种非技术性的厌恶。

    解决方案就是克服它并使用临时变量（或uniq如@ikegami 所示）。如果我需要临时变量来完成某件事，我会使用该变量，然后继续生活，担心其他事情。

    • 3 
  3. use List::Util qw( uniq );

@a = uniq @a;
    • 1

  4. 我想避免为此目的创建临时哈希变量。

    您已经为此目的创建了一个临时哈希变量。您只是没有给它命名。

    当我读到这个问题时，我想到的是你没有考虑使用词法作用域。这是 Perl 的一个关键特性。你从 perlfaq 获得的代码：

    my %hash   = map { $_, 1 } @array;
# or a hash slice: @hash{ @array } = ();
# or a foreach: $hash{$_} = 1 foreach ( @array );

my @unique = keys %hash;

#...
my %seen = ();
my @unique = grep { ! $seen{ $_ }++ } @array;

    ...可以通过将变量放入作用域中来轻松修改，以消除“临时”变量的持久性。巧合的是，这在概念上与使用相同List::Util::uniq，或者您自己的解决方案使用未命名的哈希，该哈希在使用后会被丢弃。

    my @unique;
{
    my %hash   = map { $_, 1 } @array;
    @unique = keys %hash;
}
# here %hash no longer exists
# ....
my @unique;
{
    my %seen;    # = () is redundant.
    @unique = grep { ! $seen{ $_ }++ } @array;
}
# here %seen no longer exists

    由于我们在块内声明变量{ ... }，因此在块结束后，它们不再可用。这本质上就是您的原始解决方案试图做的事情。

    后一种解决方案是有用的uniq。它还具有保留唯一元素顺序的优点。在前一种解决方案中，顺序会丢失，因为哈希是无序的。

    • 1

  5. ...但现在失败了...

    只是添加一个关于它失败的简单声明，经常被忽视。直接从文档中获取密钥

    密钥哈希

    键数组

    ...

    就是这样——keys只接受哈希或数组变量。不是引用、标量、列表——不，只是变量。

    至于应该怎么做，这里已经有了很好的答案。我更喜欢使用一个名字好听的库，而且uniqfromList::Util是最标准的库，因为这样人们就可以从房间的另一边知道这段代码的目的是什么，而几乎不需要任何认知参与。

    （或者，如果您愿意，可以编写自己的变量，根据需要创建变量，并给它起一个好听的名字。）

    • 0

相关问题