主页 / coding / 问题 / 79464748
Accepted
CleanSock
Asked: 2025-02-25 04:37:30 +0800 CST

KDB 中用于修改 col 值的代码行数更少

  • 772

我有一张如下表：

q)tab:([]time:.z.t;sym:`ax`bx`cx`ds;col1:`a`a`b`b;price:1.4,1.2,1.3,1.4)
q)tab
time         sym col1 price
---------------------------
20:29:37.309 ax  a    1.4
20:29:37.309 bx  a    1.2
20:29:37.309 cx  b    1.3
20:29:37.309 ds  b    1.4
q)

我的目标是将 col1 中的值从 a->b（其中 a 和 b->a（其中 b 和列名相同））更改为 a->b（其中 b 和列名相同）。下面是我的代码，可以完成这项工作，但是有没有更好的方法可以用更少的代码行来实现这一点？

testTab:update col2:count[i]#enlist `b from tab where col1=`a
testTab:update col2:count[i]#enlist `a from testTab where col1=`b

q)testTab
time         sym col1 price col2
--------------------------------
20:29:37.309 ax  a    1.4   b
20:29:37.309 bx  a    1.2   b
20:29:37.309 cx  b    1.3   a
20:29:37.309 ds  b    1.4   a
q)testTab:`time`sym`col2 xcols testTab  //Bring forward col2

q)testTab
time         sym col2 col1 price
--------------------------------
20:29:37.309 ax  b    a    1.4
20:29:37.309 bx  b    a    1.2
20:29:37.309 cx  a    b    1.3
20:29:37.309 ds  a    b    1.4

q)testTab: delete col1 from testTab    //Delete original col1 from the table
q)testTab: `time`sym`col1 xcol testTab  // Rename col2 to col1

q)testTab
time         sym col1 price
---------------------------
20:29:37.309 ax  b    1.4
20:29:37.309 bx  b    1.2
20:29:37.309 cx  a    1.3
20:29:37.309 ds  a    1.4
q)

谢谢！

kdb+

1 个回答

  1. Best Answer

    最简单的方法是使用字典/地图：

    q)map:`a`b!`b`a
q)
q)update map col1 from tab
time         sym col1 price
---------------------------
21:01:27.484 ax  b    1.4
21:01:27.484 bx  b    1.2
21:01:27.484 cx  a    1.3
21:01:27.484 ds  a    1.4

    如果不是所有值都要改变（即只有子集需要重新映射），那么只有改变的子集才应该在映射字典中，其余的可以^用现有值填充（）

    update col1^map col1 from tab
    • 3

相关问题