如何在 vba 中使图片透明度达到 60%？

我必须承认这比我想象的要困难得多（当然我可能把它想得太复杂了）：

Sub InsertRectangleWithImage()
    Dim ws As Worksheet
    Dim shp As Shape
    Dim imgURL As String
    Dim imgPath As String
    
    Set ws = ThisWorkbook.Sheets("Sheet1")

    imgURL = "https://cdn.hubblecontent.osi.office.net/m365content/publish/0b4f7be0-2a71-43c6-a762-bba962e256c3/182654618.jpg"

    imgPath = Environ("TEMP") & "\tempImage.jpg"
    DownloadFile imgURL, imgPath

    Set shp = ws.Shapes.AddShape(msoShapeRectangle, 50, 50, 200, 100)

    shp.Fill.UserPicture imgPath
    
    shp.Fill.Transparency = 0.4

    Kill imgPath
End Sub


Private Sub DownloadFile(URL As String, LocalFilePath As String)
    Dim WinHttpReq As Object
    Set WinHttpReq = CreateObject("WinHttp.WinHttpRequest.5.1")
    WinHttpReq.Open "GET", URL, False
    WinHttpReq.Send

    If WinHttpReq.Status = 200 Then
        Dim adoStream As Object
        Set adoStream = CreateObject("ADODB.Stream")
        adoStream.Open
        adoStream.Type = 1 ' Binary
        adoStream.Write WinHttpReq.ResponseBody
        adoStream.Position = 0 ' Set the stream position to the start
        adoStream.SaveToFile LocalFilePath, 2 ' Overwrite if file exists
        adoStream.Close
    End If
End Sub

参考形状及其Fill.Transparency属性。

Public Sub Test()

    ChangeTransparency "Picture 3", 0.6
    ChangeTransparency "Rectangle 4", 0.3
    ChangeTransparency "Graphic 6", 0.8

End Sub

Public Sub ChangeTransparency(ShapeName As String, TransparencyPercent As Double)

    Dim MyShape As Shape
    
    Set MyShape = ThisWorkbook.Worksheets("Sheet1").Shapes(ShapeName)
    MyShape.Fill.Transparency = TransparencyPercent

End Sub  

一行代码：

ThisWorkbook.Worksheets("Sheet1").Shapes("Rectangle 4").Fill.Transparency = 0.3

编辑：
看了你的第二个链接后，我认为你想要使图片透明而不是使图片背景透明，你可能已经发现如果你使用插入图片，代码不会这样做。
而是插入一个矩形并将其填充设置为图片或纹理填充。