主页 / coding / 问题 / 79349480
Accepted
Anna
Asked: 2025-01-12 15:04:21 +0800 CST

将多列的 ID 标准化为一列

  • 772

我有与产品名称、工具名称和工具 ID 相关的数据，数据示例如下：

产品名称 工具名称 ID 工具（标准） ID 工具（替代方案 1） ID 工具（替代方案 2）
产品 A 工具 A1 11-A1
产品 A 工具 A2 12-A2-01 12-A2-02 12-A2-03
产品 A 工具 A3 13-A3
产品 B 工具 B1 21-B1-01 21-B1-02
产品 B 工具 B2 22-B2
产品C 工具 C1

我想将其清理为预期的输出，如下所示： 在此处输入图片描述

对于输出，我尝试了以下公式：

=LET(
    data; C3:E11;
    row; ROW(C3:E11)-ROW(C3:C11)+1;
    column; COLUMN(C3:E11)-COLUMN(C3:C11)+1;
    sorted_data; FLATTEN(data);
    label; FLATTEN(IF(COLUMN(C3:E11)-COLUMN(C3:C11)=0; "Standard"; "Alternative"));
    result; IFERROR(FILTER(HSTACK(sorted_data; label); LEN(sorted_data)>0); HSTACK(""; ""));
    result
)

但工具类型信息没有出现，我仍然不清楚如何输入产品和工具名称，因为它一直出错。有什么改进公式的建议吗？

这是测试表链接： https: //docs.google.com/spreadsheets/d/11caWeL-PPyioovetrUf6rcy6iTb8vVuHgftAWzffpSM/edit? usp=sharing

google-sheets

3 个回答

  1. 您可以使用：

    =ARRAYFORMULA(REDUCE(
  {"Product Name"\ "Tool Name"\ "ID Tool"\ "ID Tool Type"};
  SEQUENCE(COUNTA(A3:A));
  LAMBDA(a; i; LET(
    prod; INDEX(A3:A; i);
    tool; INDEX(B3:B; i);
    ids; INDEX(C3:E; i);
    VSTACK(
      a;
      IFERROR(
        SPLIT(
          TOCOL(
            prod & "❅" & tool & "❅" & TOROW(ids; 1) & "❅" & 
            REGEXEXTRACT(FILTER(C2:E2; ids <> ""); "\((.+)\)"));
          "❅";;
        );
        {INDEX(A3:B; i)\ ""\ ""}
      )
    )))))
    • 2

  2. 尝试以下公式。请参阅文件harun24hr表。

    =VSTACK(QUERY(INDEX(SPLIT(UNIQUE(FLATTEN(INDEX(A3:A8&"|"&B3:B8&"|"&IF(C3:E8<>"";C3:E8&"|"&REGEXEXTRACT(C2:E2;"\((.+)\)");""))));"|"));"where Col3 is not null";0);QUERY(A3:D8;"Where C is null";0))

    上述公式的输出：

    产品名称 工具名称 ID 工具 ID 工具类型
    产品 A 工具 A1 11-A1 标准
    产品 A 工具 A2 12-A2-01 标准
    产品 A 工具 A2 12-A2-02 方案 1
    产品 A 工具 A2 12-A2-03 方案 2
    产品 A 工具 A3 13-A3 标准
    产品 B 工具 B1 21-B1-01 标准
    产品 B 工具 B1 21-B1-02 方案 1
    产品 B 工具 B2 22-B2 标准
    产品C 工具 C1
    • 1
  3. Best Answer

    您可以尝试：

    =reduce(tocol(;1);A3:index(A:A;match(;0/(A:A<>"")));lambda(a;c;ifna(vstack(a;let(Λ;index(C:E;row(c));Σ;transpose(ifna(filter(vstack(Λ;regexextract(C2:E2;"\((.+)\)"));Λ<>"")));
        hstack(chooserows(index(A:B;row(c));sequence(rows(Σ);1;1;0));Σ))))))

    在此处输入图片描述

    • 1

相关问题