主页 / coding / 问题 / 79348889
Accepted
jahnLudvik
Asked: 2025-01-12 05:04:42 +0800 CST

根据前 3 个布尔“真”值过滤数据的公式

  • 772

我正在尝试使用 Excel 计算第二行每个单元格前三个条目的总和，并通过第一行中的 BOOL 进行“索引”。

我希望使用偏移量来过滤，但显然不可能使用它。

现在我正在考虑使用 SUMIF 和部分和的差值，但我想找到一种更简单的方法。

输出应该是第三行。

谢谢

0 1 1 1 0 1 0 0 1 0 0 1 1 1 1 0
17 4 0 四十四 6 0 87 四十五 三十六 8 0 1 三十九 三十九 41 三十
0 0 0 0 四十八 四十八 四十四 四十四 四十四 80 80 80 三十七 76 79 119
excel

5 个回答

  1. =MAP(A1:P1,A2:P2,LAMBDA(x,y,
 LET(c,LAMBDA(e,TAKE(A1:INDEX(A:P,ROW(e),COLUMN(e)-1),-1)),
     d,TAKE(TOCOL(c(y)/c(x),2),-3),
IF(COLUMN(x)<3,0,(ROWS(d)=3)*SUM(d)))))

    这里A1:P1映射为x且。A2:P2y

    c用作函数，它需要输入e，并且只取最后一行，A1:[input range offset -1 column]这意味着如果输入是，y它将返回输入列的范围。例如，如果y是，E2 e(y)则返回TAKE(A1:D2,-1)

    接下来，d我们将 和 结合起来TOCOL(c(y)/c(x),2)，其中y前一列的值x除以 前一列的值。其中0中的任何一个x都会强制执行 #DIV/0 错误。该TOCOL参数2会跳过这些错误值。

    有可能d还不包含 3 条记录，因此将其ROWS(d)=3乘以BOOLEANSUM(d)

    或者非 LAMBDA 解决方案：

    =LET(a,A1:P1,
     s,SEQUENCE(,COLUMNS(a)),
     w,WRAPROWS(TOROW(VSTACK(s+1,A2:P2)/a,2,1),2),
     r,DROP(SEQUENCE(ROWS(w)),2),
IFNA(VLOOKUP(s,
             HSTACK(TAKE(w,-ROWS(r),1),
             MMULT(INDEX(w,r-{0,1,2},2),{1;1;1})),
             2),
     0))
    • 4
  2. Best Answer

    不是最好的，但是。公式在B3右边拖拽：

    =LET(a,TAKE(FILTER($A$2:A2,$A$1:A1=1),1,-3),IF(COUNTA(a)>=3,SUM(a),0))

    结果：

    在此处输入图片描述

    • 3

  3. 这是溢出公式，但要长得多

    =LET(bools,A1:P1,
    data,A2:P2,
    seq,SEQUENCE(1,COLUMNS(data)),
    MAP(seq,LAMBDA(i,IF(i=1,0,
      LET(c,SUM(A1:INDEX(bools,i-1)),
        IF( c<3,0,SUM(TAKE(FILTER(A2:INDEX(data,i-1),A1:INDEX(bools,i-1)),,-3))))))))
    0 1 1 1 0 1 0 0 1 0 0 1 1 1 1 0
    17 4 0 四十四 6 0 87 四十五 三十六 8 0 1 三十九 三十九 41 三十
    0 0 0 0 四十八 四十八 四十四 四十四 四十四 80 80 80 三十七 76 79 119

    我本可以使用 Take 而不是 a1:index...

    =LET(bools,A1:P1,
    data,A2:P2,
    seq,SEQUENCE(1,COLUMNS(data)),
    MAP(seq,LAMBDA(i,IF(i=1,0,
      LET(c,SUM(TAKE(bools,,i-1)),
        IF( c<3,0,SUM(TAKE(FILTER(TAKE(data,,i-1),TAKE(bools,,i-1)),,-3))))))))
    • 2

  4. 您可以使用

    =HSTACK(0,MAP(A1:O1,A2:O2,LAMBDA(α,β,IFERROR(SUM(CHOOSECOLS(FILTER(A2:β,A1:α),-1,-2,-3)),0))))

    在此处输入图片描述

    • 2

  5. 另一种方法是使用SCAN自定义LAMBDA函数来存储正在运行的布尔计数，加上每次迭代的最后 3 个“标记”值，然后MAP调用并SUM得到结果：

    =LET(
    rng, DROP(A1:P2,,-1),
    fnλ, LAMBDA([n],[a],[b],[c],LAMBDA(i,CHOOSE(i,n,a,b,c))),
    arr, SCAN(fnλ(),SEQUENCE(,COLUMNS(rng)),LAMBDA(λ,j,IF(INDEX(rng,1,j),fnλ(λ(1)+1,λ(3),λ(4),INDEX(rng,2,j)),λ))),
    HSTACK(0,MAP(arr,LAMBDA(λ,IF(λ(1)>2,SUM(λ({2,3,4})),0))))
)

    这看起来可能很多，但如果没有FILTER每次迭代的额外负担，它在更大的数据集上仍然会保持相对高效（尽管不如@Pb 的MMULT解决方案那么快）。

    • 1

相关问题