主页 / coding / 问题 / 79315592
Accepted
Roger Costello
Asked: 2024-12-29 20:32:54 +0800 CST

如何在多个文件的第一行打印唯一的字段名称？

  • 772

每个文件的第一行包含字段名称。字段名称中可能存在重复。我只想打印唯一的字段名称。以下是我尝试的：

在 Bash 文件 files_and_folders.sh 中，我输入了以下内容：

#!/bin/bash
for file in **/*.TXT ; do
   awk 'NR == 1 { for (i=1; i<=NF; i++) if (!seen[$i]) seen[$i] = 1} END { for (idx in seen) printf ("%s\n",idx) }' "${file}"
done

Bash 文件成功运行，但输出包含重复项：

AB_CODE
ACFT_CODE
AC_TYPE
ADD_INFO
AKA
ALT
ALT
ALT
ALT
ALT
ALT
ALT
ALT1_DESC
ALT2_DESC
ALT3_DESC

如何修改 AWK 程序（在 Bash 脚本中）以消除重复？

bash

2 个回答

  1. 最有效的做法可能是：

    head -q -n 1 **/*.TXT | tr -s '[:space:]' $'\n' | sort -fu

    但是如果您想使用 awk，那么使用任何 awk 您都可以执行以下操作：

    awk '
    FNR == 1 {
        for ( i=1; i<=NF; i++ ) {
            names[$i]
        }
        nextfile
    }
    END {
        for ( name in names ) {
            print name
        }
    }
' **/*.TXT

    或这样：

    awk '
    FNR == 1 {
        for ( i=1; i<=NF; i++ ) {
            if ( !seen[$i]++ ) {
                print $i
            }
        }
        nextfile
    }
' **/*.TXT

    但是在部分中创建一个seen[]数组并循环遍历它END是没有意义的，也没有意义if (!seen[$i]) seen[$i] = 1——那就是测试是否seen[$i]设置了，如果没有，则设置它，以便该语句的结果始终seen[$i]设置为1。

    • 3
  2. Best Answer

    您不能运行循环bash并为每个文件运行一个新awk进程，否则关联数组seen将为每个文件初始化awk，并且它将不知道以前调用设置的现有条目awk。

    你应该像这样一次性完成它awk：

    awk 'FNR == 1 {
   for (i=1; i<=NF; ++i) {
      uniques[$i]
   }
}
END {
   for (i in uniques)
      print i
}' **/*.TXT

AC_TYPE
AKA
ALT
ADD_INFO
AB_CODE
ALT1_DESC
ALT2_DESC
ALT3_DESC
ACFT_CODE
    • 2

相关问题