主页 / coding / 问题 / 79301615
Accepted
aenagy
Asked: 2024-12-23 03:45:49 +0800 CST

awk gsub 不会替换字段中的所有句点实例

  • 772

我正在尝试解析一些输出，以便最终可以用来declare创建多个环境变量。我遇到的问题是，awk我的语句没有替换第一个字段 ( $1) 中的所有句点。

输入来自：

etherNIC=$(nmcli --get-values NAME connection show)
nmcli connection show $etherNIC | grep -i  "ipv4.gateway\|ipv4.route" > ./ipv4settings.txt

...看起来像这样：

cat ./ipv4settings.txt
ipv4.gateway:                           192.168.2.1
ipv4.routes:                            --
ipv4.route-metric:                      -1
ipv4.route-table:                       0 (unspec)

这是输出awk：

cat ./ipv4settings.txt | awk '{ split($0, array, ":") ; gsub( "\\.", "_", $1 ) ;  gsub( ":" , "=" , $1 ) ; print $1$2 }'
ipv4_gateway=192.168.2.1
ipv4_routes=--
ipv4_route-metric=-1
ipv4_route-table=0

问题是gsub( "\\.", "_", $1 )不能替换.中的所有出现$1。我想要的输出是：

ipv4_gateway=192.168.2.1
ipv4_routes=--
ipv4_route_metric=-1
ipv4_route_table=0

在这种情况下，第二个.已被正确替换为_。

awk --version
GNU Awk 5.1.0, API: 3.0 (GNU MPFR 4.1.0-p9, GNU MP 6.2.0)
Copyright (C) 1989, 1991-2020 Free Software Foundation.
<snip>

编辑#1

我刚刚意识到的正确输出ipv4.route-table应该0 (unspec)不是0。

awk

2 个回答

  1. Best Answer

    让file.txt内容成为

    ipv4.gateway:                           192.168.2.1
ipv4.routes:                            --
ipv4.route-metric:                      -1
ipv4.route-table:                       0 (unspec)

    :请注意，您的字段与以下字段之间由多个空格字符分隔，而不是单个:。因此，我建议使用以下解决方案

    awk 'BEGIN{FS=":[[:space:]]+";OFS="="}{gsub(/[.]/,"_",$1);$1=$1;print}' file.txt

    给出输出

    ipv4_gateway=192.168.2.1
ipv4_routes=--
ipv4_route-metric=-1
ipv4_route-table=0 (unspec)

    解释：我使用FS（字段分隔符）和OFS（输出字段分隔符）来通知 GNUAWK字段在输入（）中如何剪切FS以及在输出（）中应如何分隔OFS。我使用下划线gsub替换[.]第一个字段中的文字点（），然后我这样做$1=$1是为了在没有点（即gsub什么都不做）和print整行的情况下触发字符串重建。

    （在 GNU Awk 5.3.1 中测试）

    • 1

  2. 假设/理解：

    • 我们只对以字符串开头nmcli的输出感兴趣ipv4.gatewayipv4.route
    • 我们希望替换variable: value为variable='value'
    • 所有句号和连字符都variable将被替换为下划线
    • 冒号 + 空格将被替换为等号
    • value必须用单引号引起来；如果value包含空格，则需要使用引号（例如ipv4_route_table='0 (unspec)'）

    一个awk想法：

    $ cat ipv4.awk
BEGIN                     { sq = "\x27" }                  # define single quote
/^ipv4[.](gateway|route)/ {                                # lines that start with ipv4.gateway or ipv4.route
                            gsub(/[.-]/,"_",$1)            # 1st field: replace each period/hyphen with an underscore
                            sub(/:[[:space:]]+/,"=" sq)    # replace colon + white space with equal sign and single quote
                            sub(/$/,sq)                    # append single quote on end of line
                            print                          # print current line
                          }

    笔记：

    • 而/^ipvr[.](gateway|route)/在针对 OP 的ip4vsettings.txt文件运行时则显得有些过度......
    • 可以将原始nmcli输出输入到同一脚本中以生成相同的结果

    针对 OP 的ipv4settings.txt文件进行运行：

    $ awk -f ipv4.awk ipv4settings.txt
ipv4_gateway='192.168.2.1'
ipv4_routes='--'
ipv4_route_metric='-1'
ipv4_route_table='0 (unspec)'

    应用于调用的原始输出nmcli：

    $ nmcli connection show "${etherNIC}" | awk -f ipv4.awk
ipv4_gateway='192.168.2.1'
ipv4_routes='--'
ipv4_route_metric='-1'
ipv4_route_table='0 (unspec)'
    • 1

相关问题