主页 / coding / 问题 / 79300326
Accepted
zeus
Asked: 2024-12-22 08:59:01 +0800 CST

如何在 Delphi 中使用记录实现 Builder 模式而不创建副本？

  • 772

我正在尝试使用records在 Delphi 中实现Builder 设计模式。我的目标是允许方法链接，类似于在 Kotlin、Java 或 Swift 中的做法。例如：

val alertDialog = AlertDialog.Builder(this)
    .setTitle("Builder Example")
    .setMessage("This is a builder pattern example")
    .create()

在 Delphi 中，我使用记录编写了以下代码：

type
  TAlertDialogBuilder = record
  private
    FTitle: string;
    FMessage: string;
  public
    function SetTitle(const ATitle: string): TAlertDialogBuilder;
    function SetMessage(const AMessage: string): TAlertDialogBuilder;
    procedure CreateAndShow;
  end;

implementation

function TAlertDialogBuilder.SetTitle(const ATitle: string): TAlertDialogBuilder;
begin
  FTitle := ATitle;
  Result := Self; // Creates a copy
end;

function TAlertDialogBuilder.SetMessage(const AMessage: string): TAlertDialogBuilder;
begin
  FMessage := AMessage;
  Result := Self; // Creates a copy
end;

procedure TAlertDialogBuilder.CreateAndShow;
begin
  ShowMessage(Format('Title: %s%sMessage: %s', [FTitle, sLineBreak, FMessage]));
end;

我这样使用它：

procedure ShowDialogExample;
begin
  TAlertDialogBuilder.Create
    .SetTitle('Builder Example')
    .SetMessage('This is a builder pattern example')
    .CreateAndShow;
end;

问题：

由于记录在 Delphi 中是值类型，因此在和Self等方法中返回的结果将复制该记录。这效率不高，尤其是当记录包含许多字段或大量数据时。SetTitleSetMessage

我尝试过的：

  1. 返回指向记录的指针：我修改了方法，使其返回指向记录的指针（PAlertDialogBuilder）而不是Self。虽然这避免了复制，但它使链接变得不那么直观，因为我需要取消引用指针以^进行后续调用。

  2. 使用absolute：我考虑使用absolute关键字来避免复制，但我无法找到让它用于链接方法调用的方法。

  3. 切换到类：我知道类可以避免这个问题，因为它们是引用类型，但如果可能的话，我宁愿坚持使用记录，因为它们具有轻量级的特性和值语义。

我的问题：

如何使用记录在 Delphi 中实现 Builder 模式，同时避免不必要的复制？有没有办法absolute或其他方法可以有效地实现这一点？

delphi

1 个回答

  1. Best Answer

    我需要使用 ^ 取消引用指针以便进行后续调用。

    不，你不需要。使用取消引用指针^是可选的。这是记录的：

    使用指针的扩展语法

    编译{$EXTENDED}器指令会影响插入符号 (^) 的使用。当{$X+}生效（默认）时，引用指针时可以省略插入符号。声明指针时以及解决指针指向另一个指针时的歧义时，仍需要插入符号。有关更多信息，请参阅扩展语法 (Delphi)。

    启用扩展语法后，您可以在引用指针时省略插入符号，如下例所示：

    {$X+}
 type
   PMyRec = ^TMyRec;
   TMyRec = record
     Data: Integer;
   end;

 var
   MyRec: PMyRec;

 begin
   New(MyRec);
   MyRec.Data := 42;  {#1}
 end.

    当未启用扩展语法时，标记为 {#1} 的行通常表示为：

     MyRec^.Data := 42;

    有没有其他方法可以有效地实现这一目标？

    一种选择是将 Builder 本身更改为接口类（以避免泄漏），例如：

    type
  IAlertDialogBuilderIntf = interface
    function SetTitle(const ATitle: string): IAlertDialogBuilderIntf;
    function SetMessage(const AMessage: string): IAlertDialogBuilderIntf;
    procedure CreateAndShow;
  end;

  TAlertDialogBuilderImpl = class(TInterfacedObject, IAlertDialogBuilderIntf)
  private
    FTitle: string;
    FMessage: string;
  public
    function SetTitle(const ATitle: string): IAlertDialogBuilderIntf;
    function SetMessage(const AMessage: string): IAlertDialogBuilderIntf;
    procedure CreateAndShow;
  end;

  TAlertDialog = class
    ...
    function Builder(params): IAlertDialogBuilderIntf;
    ...
  end;

implementation

function TAlertDialogBuilderImpl.SetTitle(const ATitle: string): IAlertDialogBuilderIntf;
begin
  FTitle := ATitle;
  Result := Self;
end;

function TAlertDialogBuilderImpl.SetMessage(const AMessage: string): IAlertDialogBuilderIntf;
begin
  FMessage := AMessage;
  Result := Self;
end;

procedure TAlertDialogBuilderImpl.CreateAndShow;
begin
  ShowMessage(Format('Title: %s%sMessage: %s', [FTitle, sLineBreak, FMessage]));
end;

function TAlertDialog.Builder(params): IAlertDialogBuilderIntf;
begin
  Result := TAlertDialogBuilderImp.Create as IAlertDialogBuilderIntf;
end;
    • 5

相关问题