主页 / coding / 问题 / 79297539
Accepted
ironman
Asked: 2024-12-20 22:32:06 +0800 CST

使用 Neon 累积向量并打印到标准输出（汇编）

  • 772

我发现很难找到在 Apple Silicon 上运行的良好、完整的汇编示例，特别是对于 SIMD 类型的操作，而不是不完整的、过于通用的片段。

出于我自己的好奇心，我想在 M2 机器上写一个例子......

  1. 采用一系列数字（首先内置于汇编文件中）
  2. 将它们累积为一个结果（使用 SIMD 指令）
  3. 将结果输出到 stdout

我有以下源代码，在一个名为test.s...的文件中。

.global _start
.align 2

_start:
    ;;; Load numbers into x0
    ldr x0, numbers

    ;;; Load elements from array in x0 into dedicated Neon register
    ld1 { v0. 4s }, [x0]

    ;;; Accumulate elements in vector using dedicated Neon instruction
    addv s0, v0.4s 

    ;;; Prepare formatted string
    adrp    x0, format@page
    add x0, x0, format@pageoff

    ;;; Add result to the stack for printing
    str s0, [sp, #-16]!

    ;;; Print string
    bl _printf
    mov x16, #1
    svc 0

numbers: .word 1, 2, 3, 4
format: .asciz "Answer: %u.\n"

...，使用以下命令进行组装和链接...

as -g -arch arm64 -o test.o test.s
ld -o test test.o -lSystem -syslibroot `xcrun -sdk macosx --show-sdk-path` -e _start -arch arm64

10我本来期望在运行程序时得到答案，但我得到的却不是这个。

我做错了什么？

assembly

2 个回答

  1. Best Answer

    ldr x0, numbers将从标记numbers为的地址加载x0（这只有效，因为numbers恰好位于与指令足够近的地址，在同一部分中）。因此，中的值x0将不是的地址numbers，而是存储在那里的数据。您最终将x0包含该值0x0000000200000001，并且后续的内存访问可能会崩溃。

    您应该按照顺序将地址numbers放入，就像您对下面的操作一样。x0adrp/addformat

    而且，st1应该是ld1，正如您已经提到的。

    将这些行更改为

        adrp    x0, numbers@page
    add x0, x0, numbers@pageoff
    ld1 { v0.4s }, [x0]

    使程序10为我打印正确的值。

    • 1

  2. 谢谢你们两位——在遵循clangPeter 的建议后，得到了一些有趣的结果。

    ;;; 16-byte align "numbers"
.p2align 4, 0x0               ; previously 2
numbers: .long 1, 2, 3, 4     ; previously .word

.global _start
.p2align 2                    ; reset alignment

_start:
    ;;; Back up x29 and x30, and move stack pointer
    sub sp, sp, #32
    stp x29, x30, [sp, #16]
    add x29, sp, #16

    ;;; Load numbers, as Nate has suggested
    adrp     x8, numbers@page

    ;;; Slightly different `ldr` approach, using q0
    ldr q0, [x8, numbers@pageoff]

    ;;; Accumulate vector
    addv.4s s0, v0

    ;;; Move 32-bit result to 32-bit GP register
    fmov w8, s0

    ;;; Store 64-bit register counterpart onto the stack for printing
    str x8, [sp]

    ;;; Prime string for printing
    adrp    x0, format@page
    add x0, x0, format@pageoff

    ;;; Print string
    bl _printf

    ;;; Prepare "return 0" from "int main()"
    mov w0, #0

    ;;; Restore x29, x30, and original stack pointer
    ldp x29, x30, [sp, #16]
    add sp, sp, #32

    ;;; "return 0"
    ret

format:
    .asciz "Answer: %u.\n"

    我从链接器收到以下对齐错误...

    ld: 'numbers' from 'assembly.o' at 0x100003F6C not 16-byte aligned, which cannot be encoded as a target of LDR/STR in '_start'+12 from 'assembly.o'
final section layout:
    __PAGEZERO           addr=0x00000000, size=0x100000000, fileOffset=0x00000000
    __TEXT               addr=0x100000000, size=0x00004000, fileOffset=0x00000000
        __text           addr=0x100003f30, size=0x0000005d, fileOffset=0x00003f30
        __stubs          addr=0x100003f90, size=0x0000000c, fileOffset=0x00003f90
        __unwind_info    addr=0x100003f9c, size=0x00000060, fileOffset=0x00003f9c
    __DATA_CONST         addr=0x100004000, size=0x00004000, fileOffset=0x00004000
        __got            addr=0x100004000, size=0x00000008, fileOffset=0x00004000
    __LINKEDIT           addr=0x100008000, size=0x00004000, fileOffset=0x00008000

    ...，并且需要.p2align 4, 0x0数字，才能使其工作。

    有趣的是，从编译器的角度看，使用了ldr q0, ...Instead ofld1 { v0.4s }, ...和addv.4s s0, v0Instead of addv s0, v0.4s。

    需要对对齐进行更多研究，尝试其他指令，并选择x8过度、x2或x3（也许避免参数寄存器？）。

    再次感谢您的帮助。

    • 0

相关问题