主页 / coding / 问题 / 79263341
Accepted
user1785730
Asked: 2024-12-09 04:59:31 +0800 CST

根据列创建列表

  • 772

我有一个文本文件中的数据，格式如下：

1    2
3    4
5    6
7    8
9    0

我想为每一列创建一个列表，因此：

((1 3 5 7 9) (2 4 6 8 0))

我实际上已经想出了一个可行的解决方案：

(defn make-lists []
  (let [lines (clojure.string/split-lines (slurp "input"))]
    (let [l1 (map #(parse-long (first (clojure.string/split % #" "))) lines)
          l2 (map #(parse-long (nth (clojure.string/split % #" ") 3)) lines)]
      (list l1 l2))))

但是，我认为这个解决方案存在一些问题。我实际上并不清楚map其内部是如何工作的，但我担心这会导致对输入进行两次迭代，而理论上一次迭代就足够了。

不幸的是，输入数据中每行的两个值之间有多个空格。并且clojure.string/split每个空格都会产生一个结果。因此，我nth 3在代码中随意查找 l2，我想摆脱它。

我很感激任何关于如何改进此代码的想法。

clojure

2 个回答

  1. Best Answer

    一般来说，你不应该太在意对某件事进行多次迭代。这很常见，没关系，只有当你已经证明它是一个瓶颈时才考虑优化它。

    关于空格 - 的参数str/split是正则表达式。只需使用#" +"而不是 即可#" "。

    考虑到这一点，我会这样做：

    (->> (clojure.string/split-lines "1    2\n3    4\n5    6\n7    8\n9    0")
     (map #(map parse-long (clojure.string/split % #" +")))
     (apply map list))
    • 4

  2. 为了澄清一下第一个答案，我喜欢展开开始的步骤。在 tupelo 库中，有宏let-spy，let-spy-pretty可以打印每个步骤的结果：

    (ns tst.demo.core
  (:use demo.core tupelo.core tupelo.test)
  (:require
    [tupelo.string :as str]
    ))

(verify    ; like `deftest` but doesn't need a test name symbol
  (let-spy-pretty
    [text        " 1    2
                   3    4
                   5    6
                   7    8
                   9    0 "
     lines-orig  (str/split-lines text)
     lines-clean (mapv str/trim lines-orig)
     data-str    (mapv #(str/split % #" +") lines-clean)
     data-int    (for [pair data-str]
                   (mapv #(parse-long %) pair))
     data-cols   (apply mapv vector data-int)

     ]
    (is= data-cols
      [[1 3 5 7 9]
       [2 4 6 8 0]]
      )))

    结果：

    
-------------------------------
   Clojure 1.12.0    Java 21
-------------------------------

Testing tst.demo.core
text =>
" 1    2\n                   3    4\n                   5    6\n                   7    8\n                   9    0 "
lines-orig =>
[" 1    2"
 "                   3    4"
 "                   5    6"
 "                   7    8"
 "                   9    0 "]
lines-clean =>
["1    2" "3    4" "5    6" "7    8" "9    0"]
data-str =>
[["1" "2"] ["3" "4"] ["5" "6"] ["7" "8"] ["9" "0"]]
data-int =>
[[1 2] [3 4] [5 6] [7 8] [9 0]]
data-cols =>
[[1 3 5 7 9] [2 4 6 8 0]]

Ran 2 tests containing 1 assertions.
0 failures, 0 errors.

    我喜欢(str/trim ...)在流程早期使用，在解析/分割行、解析为 int/float 等之前删除所有前导/尾随空格（和换行符！）。我还喜欢使用mapv而不是因为map它是非惰性的并且总是产生一个矢量结果（更容易剪切/粘贴到单元测试中而无需引用）。

    一切正常后，只需替换let-spy-pretty为let并按正常格式进行格式化即可。我通常不费心用->或其他东西来压缩各个步骤，因此对于后续的代码读者来说，转换是如何一步步发生的会更加明显（特别是如果他们需要修改某些内容或添加调试打印语句）。

    • 0

相关问题