主页 / coding / 问题 / 79262686
Accepted
Shawn Zhang
Asked: 2024-12-08 22:46:08 +0800 CST

如何将 Map.adjust 转换为 monadic？

  • 772

在代码中它运行良好，如下所示

divide :: Int -> Int -> Either String Int
divide a 0 = Left "Error with 0"
divide a b = Right (a `div` b)

要更改的代码

Map.adjust (divide 3) "A" $ Map.fromList [("A",3),("B",0)]

预期结果应该是：

Map.adjust (divide 3) "A" $ Map.fromList [("A",3),("B",0)] 
=>  Right $ Map.fromList [("A",1),("B",0)]   

Map.adjust (divide 3) "B" $ Map.fromList [("A",3),("B",0)]
=>  Left "Error with 0"

或者一般来说如何构建如下函数：

Map.adjust:: (a -> m a) -> k -> (Map k a) -> m (Map k a)

非常感谢 ！

dictionary

2 个回答

  1. Best Answer

    可以在已经存在的函数之上定义adjustM具有类型的函数。(a -> m a) -> k -> (Map k a) -> m (Map k a)alterF :: (Functor f, Ord k) => (Maybe a -> f (Maybe a)) -> k -> Map k a -> f (Map k a)

    alterF更为通用，因为除了允许效果之外，它还允许您删除目标值，或者在键不存在时插入它。（这就是Maybe签名中的那些 s 的用途）。

    adjustM :: (Ord k, Applicative m) => (a -> m a) -> k -> Map k a -> m (Map k a)
adjustM f = Map.alterF (\ma -> case ma of
   -- No value? We do nothing.
   Nothing -> pure Nothing
   -- There's a value? We transform it.
   Just v -> Just <$> f v)

    或者更简洁地说，

    adjustM :: (Ord k, Applicative m) => (a -> m a) -> k -> Map k a -> m (Map k a)
adjustM f = Map.alterF (traverse f)
    • 9

  2. 我们可以使用insert以下方法来实现：

    updateM :: (Ord k, Applicative m) => (a -> m a) -> k -> Map k a -> m (Map k a)
updateM f k map = case (map !? k) of
  Just v -> flip (insert k) map <$> f v
  _ -> pure map

    因此，我们首先检查键是否存在，如果存在则运行f v，然后使用该键在中插入新值map。

    这将产生预期的结果：

    ghci> updateM (divide 3) "A" $ Data.Map.fromList [("A",3),("B",0)]
Right (fromList [("A",1),("B",0)])
ghci> updateM (divide 3) "B" $ Data.Map.fromList [("A",3),("B",0)]
Left "Error with 0"
    • 2

相关问题