主页 / coding / 问题 / 79262346
Accepted
Srikanth
Asked: 2024-12-08 19:24:31 +0800 CST

从分隔字符串中提取单词[重复]

  • 772

我收到了一个包含分隔字符串的数据集，我需要从该数据中提取特定的单词。

审计类型 实际结果
类似（BAU）流程 相似的
硬限制 - QA 时间流程 质量保证时间
1 – 类似（BAU）审计 相似的
5 – 质量保证时间 质量保证时间
3 - OTT/LP 审计 互联网
2 - 硬限制/训练 硬限制
4 - EXTND OTT/LP 审计 互联网
硬限制 硬限制
OTT/LP 审计 互联网
OTT 审计 互联网
EXTND OTT 审计 互联网

我得到了结果，但作为一名学习者，我正在寻找比这个公式更好的解决方案。

=LET(a,$A$2:$A$12,b,IFS(SEARCH("Similar",a),"Similar"),c,IFS(SEARCH("OTT",a),"OTT"),d,IFS(SEARCH("QA Time",a),"QA Time"),e,IFS(SEARCH("Hard Limit",a),"Hard Limit"),IFERROR(b,IFERROR(c,IFERROR(d,IFERROR(e,a)))))

谢谢。

图片

excel

1 个回答

  1. Best Answer

    如果您不必担心一个Actual Result包含在另一个中Actual Result，那么您可以使用查找表。在下面的公式中，

    • 这Lookup Table是硬编码的
      • 您可以创建一个单独的查找表并在公式中引用该表
    • 我使用了Table具有结构化引用的结构，该结构使公式能够自动填充列并根据插入或删除进行调整
      • 如果愿意的话，您可以将其更改为常规寻址。
    • ***请注意，如果“审计类型”中有多个关键字，则只会返回第一个关键字（按关键字列表中的顺序排列）。您的第二个审计类型也是如此。
    =LET(
    a, {"Similar"; "QA Time"; "OTT"; "Hard Limit"},
    INDEX(a, XMATCH(TRUE, ISNUMBER(SEARCH(a, [@[Audit Type]]))))
)

    在此处输入图片描述

    如果一行中有多个Keyword，比如第二行，并且您希望返回所有行，则可以使用以下公式：*（请注意，这里我使用了一个单独的表进行查找，名为Keywords）

    =ARRAYTOTEXT(
    CHOOSEROWS(
        Keywords,
        LET(
            a, BYROW(
                Keywords,
                LAMBDA(arr, ISNUMBER(SEARCH(arr, [@[Audit Type]])))
            ) * SEQUENCE(ROWS(Keywords)),
            b, FILTER(a, a > 0),
            b
        )
    )
)

    在此处输入图片描述

    如果一个关键字包含在另一个关键字中存在问题，那么您可能应该寻找使用正则表达式的解决方案。

    目前只有 Insider 版本具有正则表达式，但您可以使用 VBA 或 Python 在 Excel 中实现它。

    • 1

相关问题