主页 / coding / 问题 / 79245350
Accepted
tjwrona
Asked: 2024-12-03 03:30:26 +0800 CST

为什么将 DateTime 截断为“天”会导致我在减去一天时得到错误的结果？

  • 772

给定当前日期，我需要使用 Perl DateTime模块获取昨天的日期。

当天的当前时间并不重要。我只需要昨天的日期，所以我认为我可以在减去一天之前截断当天的时间值。

这看起来应该足够简单，但我最终得到了错误的结果。

use DateTime;
use strict;
use warnings;

my $today = DateTime->now(time_zone => 'local');

# Set time zone to UTC before performing math (see DateTime documentation)
$today->set_time_zone('UTC');
my $yesterday = $today->clone->truncate(to => 'day')->subtract(days => 1);

# Set time zone back to local
$today->set_time_zone('local');
$yesterday->set_time_zone('local');

print "YESTERDAY: ".$yesterday->strftime("%m/%d/%Y")."\n";
print "    TODAY: ".$today->strftime("%m/%d/%Y")."\n";

此代码输出：

YESTERDAY: 11/30/2024
    TODAY: 12/02/2024

请注意，如果我不这样做，->truncate(to => 'day')我似乎会得到正确的结果，但我仍然对截断日期时间会导致结果改变这一事实感到困惑。

有人知道为什么会发生这种情况吗？

datetime

1 个回答

  1. Best Answer

    使用floating而不是UTC。

    $today->set_time_zone( $tz );并非简单地将时区更改为$tz；它将时间戳从其当前时区转换为指定时区。这会导致日期更改。

    我将稍微重新整理一下您的代码，以便更好地说明正在发生的事情。以下内容与您拥有的内容相同，并在注释中提供了一个示例：

    my $now_local = DateTime->now( time_zone => 'local' );     # 2024-12-02T01:30:00+02:00
my $now_utc = $now_local->clone->set_time_zone( 'UTC' );   # 2024-12-01T23:30:00Z
my $today = $now_utc->clone->truncate( to => 'day' );      # 2024-12-01
my $yesterday = $today->clone->subtract( days => 1 );      # 2024-11-30

say $now_local->strftime( "%F" );  # 2024-12-02
say $yesterday->strftime( "%F" );  # 2024-11-30

    您应该使用floating而不是UTC。这实际上会删除时区。这就像将时间设置为 UTC，但不转换时间。

    my $now_local = DateTime->now( time_zone => 'local' );     # 2024-12-02T01:30:00+02:00
my $now = $now_local->clone->set_time_zone( 'floating' );  # 2024-12-02T01:30:00
my $today = $now_utc->clone->truncate( to => 'day' );      # 2024-12-02
my $yesterday = $today->clone->subtract( days => 1 );      # 2024-12-01

say $now_local->strftime( "%F" );  # 2024-12-02
say $yesterday->strftime( "%F" );  # 2024-12-01

    使用浮动时区进行日期计算可以避免夏令时和其他小的不连续性问题，但如果跳过一整天，它仍然会失败。2011 年在萨摩亚发生了这种情况，当时它将其偏移量更改为日期变更线的另一侧。DateTime 需要能够操纵本地日期的功能来解决这个问题。

    • 5

相关问题