主页 / coding / 问题 / 79186829
Accepted
Kram Kramer
Asked: 2024-11-14 06:08:16 +0800 CST

如何在 Excel 中按多个条件对项目进行排名

  • 772

1）复制以下值并粘贴到Excel 表中的A1:E9单元格中。

玩家 积分 助攻 首先对 B 列进行排序，然后对 C 列进行排序 仅限 B 列的唯一排名
安迪 10 8 =RANK.EQ($B2,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B2,$C$2:$C$9,">"&$C2) =RANK.EQ($B2,$B$2:$B$9)+COUNTIFS($B$2:B2,B2)-1
伯纳德 10 2 =RANK.EQ($B3,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B3,$C$2:$C$9,">"&$C3) =RANK.EQ($B3,$B$2:$B$9)+COUNTIFS($B$2:B3,B3)-1
卡尔 6 4 =RANK.EQ($B4,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B4,$C$2:$C$9,">"&$C4) =RANK.EQ($B4,$B$2:$B$9)+COUNTIFS($B$2:B4,B4)-1
德里克 6 3 =RANK.EQ($B5,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B5,$C$2:$C$9,">"&$C5) =RANK.EQ($B5,$B$2:$B$9)+COUNTIFS($B$2:B5,B5)-1
艾琳 8 6 =RANK.EQ($B6,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B6,$C$2:$C$9,">"&$C6) =RANK.EQ($B6,$B$2:$B$9)+COUNTIFS($B$2:B6,B6)-1
坦率 8 6 =RANK.EQ($B7,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B7;$C$2:$C$9,">"&$C7) =RANK.EQ($B7,$B$2:$B$9)+COUNTIFS($B$2:B7,B7)-1
格雷格 3 6 =RANK.EQ($B8,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B8,$C$2:$C$9,">"&$C8) =RANK.EQ($B8,$B$2:$B$9)+COUNTIFS($B$2:B8,B8)-1
哈利 2 9 =RANK.EQ($B9,$B$2:$B$9)+COUNTIFS($B$2:$B$9,$B9,$C$2:$C$9,">"&$C9) =RANK.EQ($B9,$B$2:$B$9)+COUNTIFS($B$2:B9,B9)-1

2）请看下面的图片。

这就是图片。

3）我的问题的解释如下：

D 列中的公式将B 列排在第一位，然后是C 列。

D 列中的公式对重复项进行排序。

D 列中不存在数字 4 ，因为Erin和Frank的值相等。

E 列中的公式仅对 B 列进行排名。

E 列中的公式不会对重复项进行排名。

E 列中存在数字 4 ，因为E 列中的公式 没有对重复项进行排名。

我更喜欢使用E 列中的公式，因为E 列中的公式不会对重复项进行排名。

4）我的问题是：

请改进E 列中的公式，该公式应该首先对B 列进行排序，然后再对C 列进行排序。

excel

3 个回答

  1. Best Answer

    公式位于单元格 D25 中

    =RANK.EQ($B25,$B$25:$B$32)+COUNTIFS($B$25:$B$32,$B25,$C$25:$C$32,">"&$C25)+COUNTIFS(B$24:B24,B25,C$24:C24,C25)

    由于它占据了表格上方的一行，因此表格不能从第 1 行开始。如果有标题，则它可以工作并返回以下结果：

    在此处输入图片描述

    • 2

  2. 对于早期版本的 Excel：

    =RANK(B9, $B$2:$B$9) + COUNTIF($B$2:B9, B9) - 1 + (C9 / 100)

    您必须将数字格式化为不显示小数点。

    在此处输入图片描述

    如果您有 Excel 365，则可以使用：

    =SORTBY(SEQUENCE(ROWS(B2:B9)), -(B2:B9 + C2:C9/100))

    在此处输入图片描述

    • 1

  3. 对于三个标准：

    =RANK.EQ(B2,$B$2:$B$9)
+ COUNTIFS(B$2:$B$9,B2,C$2:C$9,">" & C2)
+ COUNTIFS(B$2:B$9,B2, C$2:C$9,C2,D$2:D$9,">" & D2)
+ COUNTIFS(B$2:B2,B2,C$2:C2,C2,D$2:D2,D2) - 1

    三个标准结果和临时步骤

    抱歉，无法想出更简短的公式，但您可以尝试一下：

    • 假设不属于助攻0的值
    • 对于二次排序，匹配单元格，协助对数组进行排序
      (B2=$B$2:$B$9) * $C$2:$C$9
    • 输入F2并向下填充（可能需要使用Control+Shift+Enter输入）
    =RANK.EQ($B2,$B$2:$B$9)
+MATCH(C2,LARGE((B2=$B$2:$B$9) * $C$2:$C$9,ROW($C$2:$C$9) - ROW($C$1)),0) - 1
+COUNTIFS($B$2:$B2,$B2,$C$2:$C2,$C2) - 1

    采取临时措施：

    临时措施

    与使用以下方法得到的结果进行比较SORTBY：

    结果

    • 1

相关问题